Cómo configurar variantes de compilación

Esta página se basa en las especificaciones de Descripción general de la configuración de tu compilación con el propósito de mostrarte la manera de configurar variantes de compilación para crear diferentes versiones de tu app a partir de un mismo proyecto, y de administrar correctamente tus dependencias y configuraciones de firma.

Cada variante de compilación representa una versión diferente de tu app que puedes compilar. Por ejemplo, es posible que desees compilar una versión de tu app que sea gratuita, con contenido limitado, y una versión paga que incluya más contenido. También puedes compilar diferentes versiones de tu app para diferentes dispositivos, según el nivel de API y otras variantes de dispositivos. No obstante, si deseas compilar diferentes versiones según la ABI del dispositivo o la densidad de pantalla, puedes compilar varios APK.

Las variantes de compilación surgen del uso de un conjunto específico de reglas a través de Gradle para combinar configuraciones, código y recursos configurados en tus tipos de compilación y variantes de productos. Aunque no configuras variantes de compilación directamente, sí configuras los tipos de compilación y las variantes de productos que las forman.

Por ejemplo, en una variante de producto "demo", pueden especificarse diferentes funciones y requisitos de dispositivo, como código fuente personalizado, recursos y niveles de API mínimos, mientras que en la variante de compilación "debug" se aplican diferentes configuraciones de compilación y empaquetado, como opciones de depuración y claves de firma. La variante de compilación resultante es la versión "demoDebug" de tu app; esta contiene una combinación de configuraciones y recursos incluidos en la variante de producto "demo", el tipo de compilación "debug" y el conjunto de orígenes main/.

Cómo configurar tipos de compilaciones

Puedes crear y configurar tipos de compilación en el archivo build.gradle del nivel del módulo dentro del bloque android. Cuando creas un módulo nuevo, Android Studio genera automáticamente los tipos de compilación de depuración y lanzamiento. Si bien el tipo de compilación de depuración no aparece en el archivo de configuración de compilación, Android Studio lo configura con debuggable true. Esta configuración te permite depurar la app en dispositivos Android seguros y configura la firma de la app con un almacén de claves de depuración genérico.

Puedes agregar el tipo de compilación de depuración a tu configuración si deseas agregar o cambiar determinadas opciones de configuración. En el siguiente ejemplo, se especifica un applicationIdSuffix para el tipo de compilación de depuración y se configura un tipo de compilación "staging" (etapa de pruebas) que se inicializa con la configuración del tipo de compilación de depuración.

Groovy

android {
    defaultConfig {
        manifestPlaceholders = [hostName:"www.example.com"]
        ...
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        debug {
            applicationIdSuffix ".debug"
            debuggable true
        }

        /**
         * The `initWith` property allows you to copy configurations from other build types,
         * then configure only the settings you want to change. This one copies the debug build
         * type, and then changes the manifest placeholder and application ID.
         */
        staging {
            initWith debug
            manifestPlaceholders = [hostName:"internal.example.com"]
            applicationIdSuffix ".debugStaging"
        }
    }
}

Kotlin

android {
    defaultConfig {
        manifestPlaceholders["hostName"] = "www.example.com"
        ...
    }
    buildTypes {
        getByName("release") {
            isMinifyEnabled = true
            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
        }

        getByName("debug") {
            applicationIdSuffix = ".debug"
            isDebuggable = true
        }

        /**
         * The `initWith` property allows you to copy configurations from other build types,
         * then configure only the settings you want to change. This one copies the debug build
         * type, and then changes the manifest placeholder and application ID.
         */
        create("staging") {
            initWith(getByName("debug"))
            manifestPlaceholders["hostName"] = "internal.example.com"
            applicationIdSuffix = ".debugStaging"
        }
    }
}

Nota: Cuando realizas cambios en un archivo de configuración de la compilación, Android Studio exige que sincronices tu proyecto con la nueva configuración. Para hacerlo, haz clic en Sync Now en la barra de notificaciones que aparece cuando realizas un cambio, o bien en Sync Project  en la barra de herramientas. Si Android Studio detecta un error en la configuración, aparecerá la ventana Messages con la descripción del problema.

Para obtener más información sobre todas las propiedades que puedes configurar con tipos de compilación, lee la referencia DSL de BuildType.

Cómo configurar tipos de productos

Crear variantes de productos es similar a crear tipos de compilación: agrégalas al bloque productFlavors de tu configuración e incluye los ajustes que desees. Las variantes de productos admiten las mismas propiedades que defaultConfig. Esto se debe a que defaultConfig en realidad pertenece a la clase ProductFlavor. Eso significa que puedes proporcionar la configuración básica para todas las variantes en el bloque defaultConfig, y cada una puede cambiar cualquiera de estos valores predeterminados; por ejemplo, applicationId. Para obtener más información sobre el ID de aplicación, consulta Cómo configurar el ID de aplicación.

Nota: No obstante, debes especificar un nombre de paquete usando el atributo package en el archivo de manifiesto main/. También debes usar ese nombre de paquete en tu código fuente para hacer referencia a la clase R, o bien resolver cualquier actividad o registro de servicio relacionados, Esto te permite usar applicationId a fin de asignar a cada variante de producto un ID exclusivo para el empaquetado y la distribución, sin necesidad de cambiar el código fuente.

Todas las variantes deben pertenecer a una dimensión denominada, que es un grupo de variantes de productos. Debes asignar todos los tipos a una dimensión; de lo contrario, obtendrás el siguiente error de compilación. Si un módulo dado especifica solo una dimensión de variantes, el complemento de Gradle para Android asignará automáticamente todas las variantes del módulo a esa dimensión.

  Error:All flavors must now belong to a named flavor dimension.
  The flavor 'flavor_name' is not assigned to a flavor dimension.

En la siguiente muestra de código, se crea una dimensión de tipo denominada "version" y se agregan las variantes de producto "demo" y "full". Estas variantes brindan sus propios applicationIdSuffix y versionNameSuffix:

Groovy

android {
    ...
    defaultConfig {...}
    buildTypes {
        debug{...}
        release{...}
    }
    // Specifies one flavor dimension.
    flavorDimensions "version"
    productFlavors {
        demo {
            // Assigns this product flavor to the "version" flavor dimension.
            // If you are using only one dimension, this property is optional,
            // and the plugin automatically assigns all the module's flavors to
            // that dimension.
            dimension "version"
            applicationIdSuffix ".demo"
            versionNameSuffix "-demo"
        }
        full {
            dimension "version"
            applicationIdSuffix ".full"
            versionNameSuffix "-full"
        }
    }
}

Kotlin

android {
    ...
    defaultConfig {...}
    buildTypes {
        getByName("debug"){...}
        getByName("release"){...}
    }
    // Specifies one flavor dimension.
    flavorDimensions "version"
    productFlavors {
        create("demo") {
            // Assigns this product flavor to the "version" flavor dimension.
            // If you are using only one dimension, this property is optional,
            // and the plugin automatically assigns all the module's flavors to
            // that dimension.
            dimension = "version"
            applicationIdSuffix = ".demo"
            versionNameSuffix = "-demo"
        }
        create("full") {
            dimension = "version"
            applicationIdSuffix = ".full"
            versionNameSuffix = "-full"
        }
    }
}

Nota: En el caso de apps heredadas que se distribuyen con APK en Google Play (que se crearon antes de agosto de 2021), si deseas distribuir tu app con la Compatibilidad con varios APK en Google Play, asigna el mismo valor de applicationId a todas las variantes y otorga a cada variante un versionCode diferente. Para distribuir diferentes variantes de tu app como apps independientes en Google Play, debes asignar un applicationId distinto a cada variante.

Después de crear y configurar tus tipos de productos, haz clic en Sincronizar ahora en la barra de notificaciones. Una vez que se completa la sincronización, Gradle crea automáticamente variantes de compilación según tus tipos de compilación y variantes de productos, y les asigna nombres según <product-flavor><Build-Type>. Por ejemplo, si creaste tipos de producto "demo" y "full", y conservaste los tipos de compilación predeterminados de "debug" y "release" (lanzamiento), Gradle crea las siguientes variantes de compilación:

  • demoDebug
  • demoRelease
  • fullDebug
  • fullRelease

Puedes cambiar la variante de compilación por la que desees para la compilación y la ejecución. Simplemente, dirígete a Build > Select Build Variant y selecciona una del menú desplegable. Sin embargo, para comenzar a personalizar cada variante de compilación con sus propias funciones y recursos, deberás saber cómo crear y administrar conjuntos de fuentes.

Cómo combinar varios tipos de productos con dimensiones de tipos

En algunos casos, es probable que desees combinar la configuración de varios tipos de productos. Por ejemplo, puedes crear diferentes configuraciones para los tipos de productos "completo" y "demostración" que se basen en el nivel de API. Para hacerlo, el complemento de Android para Gradle te permite crear varios grupos de productos como dimensiones de tipos. Cuando compilas tu app, Gradle combina una configuración de tipo de producto de cada dimensión de tipo que defines, junto con una configuración de tipo de compilación, para crear la variante de compilación final. Gradle no combina variantes de producto que pertenecen a la misma dimensión de variantes.

En la siguiente muestra de código, se usa la propiedad flavorDimensions a fin de crear una dimensión de variantes "mode" y agrupar las variantes de producto "full" y "demo", así como crear una dimensión de variantes "api" para agrupar las configuraciones de variantes de productos basadas en el nivel de API:

Groovy

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion 24
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion 23
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion 21
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    getByName("debug") {...}
    getByName("release") {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions("api", "mode")

  productFlavors {
    create("demo") {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension = "mode"
      ...
    }

    create("full") {
      dimension = "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    create("minApi24") {
      dimension = "api"
      minSdkVersion(24)
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode = 30000 + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi24"
      ...
    }

    create("minApi23") {
      dimension = "api"
      minSdkVersion(23)
      versionCode = 20000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi23"
      ...
    }

    create("minApi21") {
      dimension = "api"
      minSdkVersion(21)
      versionCode = 10000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi21"
      ...
    }
  }
}
...

La cantidad de variantes de compilación que crea Gradle es igual al producto de la cantidad de variantes de cada dimensión de variantes y la cantidad de tipos de compilación que configuras. Cuando Gradle asigna un nombre a cada variante de compilación o artefacto correspondiente, las variantes de producto pertenecientes a la dimensión de variantes de mayor prioridad aparecen primero; luego, aparecen aquellas de dimensiones de menor prioridad y, por último, el tipo de compilación. Con la configuración de compilación anterior como ejemplo, Gradle crea un total de 12 variantes de compilación con el siguiente esquema de nomenclatura:

Variante de compilación: [minApi24, minApi23, minApi21][Demo, Full][Debug, Release]
APK correspondiente: app-[minApi24, minApi23, minApi21]-[demo, full]-[debug, release].apk
Por ejemplo:
Variante de compilación: minApi24DemoDebug
APK correspondiente: app-minApi24-demo-debug.apk

Además de los directorios de conjuntos de orígenes que puedes crear para cada variante de producto y de compilación en particular, también puedes crear directorios de conjuntos de orígenes para cada combinación de tipos de productos. Por ejemplo, puedes crear y agregar fuentes Java al directorio src/demoMinApi24/java/, y Gradle usa esas fuentes únicamente cuando compila una variante que combina esos dos tipos de productos. Los conjuntos de fuentes que creas para las combinaciones de tipos de productos tienen una prioridad superior con respecto a aquellos que pertenecen a cada tipo de producto en particular. Para obtener más información sobre los conjuntos de orígenes y la manera en que Gradle combina recursos, consulta la sección Cómo crear conjuntos de orígenes.

Cómo filtrar variantes

Gradle crea una variante de compilación para cada combinación posible de los tipos de productos y de compilación que configuras. Sin embargo, es posible que determinadas variantes de compilación no sean necesarias o no tengan sentido en el contexto de tu proyecto. Puedes quitar determinadas configuraciones de variantes de compilación creando un filtro de variantes en tu archivo build.gradle de nivel de módulo.

Con la configuración de compilación de la sección anterior como ejemplo, supongamos que planeas incluir compatibilidad solo a partir del nivel de API 23 para la versión de demostración de la app. Puedes usar el bloque variantFilter a fin de filtrar todas las configuraciones de variantes de compilación que combinan las variantes de producto "minApi21" y "demo":

Groovy

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

Kotlin

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    create("demo") {...}
    create("full") {...}
    create("minApi24") {...}
    create("minApi23") {...}
    create("minApi21") {...}
  }
}

androidComponents {
    beforeVariants { variantBuilder ->
        // To check for a certain build type, use variantBuilder.buildType == "<buildType>"
        if (variantBuilder.productFlavors.containsAll(listOf("api" to "minApi21", "mode" to "demo"))) {
            // Gradle ignores any variants that satisfy the conditions above.
            variantBuilder.enabled = false
        }
    }
}
...

Una vez que agregas un filtro de variantes a tu configuración de compilación y haces clic en Sync Now en la barra de notificaciones, Gradle omite cualquier variante de compilación que cumpla con las condiciones que especifiques, y estas dejan de aparecer en el menú desplegable cuando haces clic en Build > Select Build Variant en la barra de menú (o Build Variants en la barra de la ventana de herramientas).

Cómo crear conjuntos de orígenes

De forma predeterminada, Android Studio crea el conjunto de orígenes y los directorios de main/ para todo lo que desees compartir entre todas tus variantes de compilación. Sin embargo, puedes crear nuevos conjuntos de orígenes a fin de controlar exactamente los archivos que compila y empaqueta Gradle para tipos de compilación, variantes de productos (y combinaciones de esas variantes cuando se usan dimensiones de variantes) y variantes de compilación específicos. Por ejemplo, puedes definir una funcionalidad básica en el conjunto de orígenes de main/ y usar conjuntos de orígenes de variantes de productos a los efectos de cambiar el desarrollo de la marca de tu app para diferentes clientes, o bien incluir permisos y funcionalidad de acceso especiales solo para variantes de compilación que usan el tipo de compilación de depuración.

Gradle prevé que organices los directorios y archivos de conjuntos de fuentes de una forma determinada, caso similar al del conjunto de fuentes main/. Por ejemplo, Gradle espera que los archivos de clase de Java específicos de tu tipo de compilación "debug" se ubiquen en el directorio src/debug/java/.

El complemento de Android para Gradle proporciona una tarea de Gradle útil que te muestra la manera de organizar tus archivos para cada tipo de compilación, así como variantes de producto y de compilación. Por ejemplo, en el siguiente caso del resultado de tarea, se describe el punto en el cual Gradle prevé que encontrará ciertos archivos para el tipo de compilación de "depuración":

------------------------------------------------------------
Project :app
------------------------------------------------------------

...

debug
----
Compile configuration: compile
build.gradle name: android.sourceSets.debug
Java sources: [app/src/debug/java]
Manifest file: app/src/debug/AndroidManifest.xml
Android resources: [app/src/debug/res]
Assets: [app/src/debug/assets]
AIDL sources: [app/src/debug/aidl]
RenderScript sources: [app/src/debug/rs]
JNI sources: [app/src/debug/jni]
JNI libraries: [app/src/debug/jniLibs]
Java-style resources: [app/src/debug/resources]

Para ver este resultado, haz lo siguiente:

  1. Haz clic en Gradle a la derecha de la ventana de IDE.
  2. Navega a MyApplication > Tasks > Android y haz doble clic en sourceSets. Después de que Gradle ejecute la tarea, se abrirá la ventana Run para mostrar el resultado.
  3. Si la pantalla no está en modo texto, como se muestra arriba, haz clic en Toggle view , en el lado izquierdo de la ventana Run.

Nota: En el resultado de la tarea, también se muestra la manera de organizar los conjuntos de orígenes para archivos que desees usar en la ejecución de pruebas de tu app, como los conjuntos de orígenes de prueba test/ y androidTest/.

Cuando creas una nueva variante de compilación, Android Studio no crea los directorios del conjunto de fuentes, pero te ofrece algunas opciones que te ayudarán. Por ejemplo, si solo quieres crear el directorio java/ para tu tipo de compilación "debug", haz lo siguiente:

  1. Abre el panel Proyecto y selecciona la vista Proyecto en el menú desplegable de la parte superior del panel.
  2. Navega a MyProject/app/src/.
  3. Haz clic con el botón derecho en el directorio src y selecciona New > Folder > Java Folder.
  4. En el menú desplegable junto a Target Source Set, selecciona debug.
  5. Haz clic en Finish.

Android Studio crea un directorio de conjunto de fuentes para tu tipo de compilación de depuración y luego crea el directorio java/ dentro de este. De manera alternativa, puedes hacer que Android Studio cree los directorios cuando agregues un nuevo archivo a tu proyecto para una variante de compilación específica. Por ejemplo, a fin de crear un archivo XML de valores para tu tipo de compilación "debug", haz lo siguiente:

  1. En el mismo panel de Project, haz clic con el botón derecho en el directorio src y selecciona New > XML > Values XML File.
  2. Ingresa el nombre del archivo XML o mantén el nombre predeterminado.
  3. En el menú desplegable junto a Target Source Set, selecciona debug.
  4. Haz clic en Finish.

Como el tipo de compilación de "depuración" se especificó como conjunto de fuentes de destino, Android Studio genera automáticamente los directorios necesarios cuando se crea el archivo XML. La estructura del directorio resultante debería ser como la que se muestra en la figura 2.

Figura 2: Nuevos directorios de conjuntos de orígenes para el tipo de compilación "debug"

Usando el mismo procedimiento, también puedes crear directorios de conjunto de orígenes para variantes de productos (por ejemplo, src/demo/) o de compilación (por ejemplo, src/demoDebug/). Además, puedes crear conjuntos de fuentes de prueba para variantes de compilación específicas; por ejemplo, src/androidTestDemoDebug/. Si deseas obtener más información, lee acerca de cómo probar conjuntos de orígenes.

Cómo cambiar configuraciones predeterminadas de conjuntos de fuentes

Si tienes orígenes que no están organizados en la estructura predeterminada del archivo de conjunto de orígenes que prevé Gradle, como se describe antes en la sección Cómo crear conjuntos de orígenes, puedes usar el bloque sourceSets para cambiar la ubicación en la que Gradle espera reunir los archivos para cada componente de un conjunto de orígenes. No es necesario que reubiques los archivos; solo debes proporcionar a Gradle las rutas de acceso, en relación con el archivo build.gradle de nivel de módulo, en las que Gradle debe encontrar los archivos para cada componente del conjunto de fuentes. Para determinar los componentes que puedes configurar y confirmar si puedes asignarlos a varios archivos o directorios, consulta la referencia de la API sobre el complemento de Android para Gradle.

En la siguiente muestra de código, se asignan fuentes del directorio app/other/ a determinados componentes del conjunto de fuentes de main y se cambia el directorio raíz del conjunto de fuentes de androidTest.

Groovy

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // If you list multiple directories, Gradle uses all of them to collect
      // sources. Because Gradle gives these directories equal priority, if
      // you define the same resource in more than one directory, you get an
      // error when merging resources. The default directory is 'src/main/res'.
      res.srcDirs = ['other/res1', 'other/res2']

      // Note: You should avoid specifying a directory which is a parent to one
      // or more other directories you specify. For example, avoid the following:
      // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
      // You should specify either only the root 'other/res1' directory, or only the
      // nested 'other/res1/layouts' and 'other/res1/strings' directories.

      // For each source set, you can specify only one Android manifest.
      // By default, Android Studio creates a manifest for your main source
      // set in the src/main/ directory.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying the
      // configuration below for the androidTest source set, Gradle looks for Java
      // sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

Kotlin

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.setSrcDirs("other/java")

      // If you list multiple directories, Gradle uses all of them to collect
      // sources. Because Gradle gives these directories equal priority, if
      // you define the same resource in more than one directory, you get an
      // error when merging resources. The default directory is 'src/main/res'.
      res.setSrcDirs("other/res1", "other/res2")

      // Note: You should avoid specifying a directory which is a parent to one
      // or more other directories you specify. For example, avoid the following:
      // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
      // You should specify either only the root 'other/res1' directory, or only the
      // nested 'other/res1/layouts' and 'other/res1/strings' directories.

      // For each source set, you can specify only one Android manifest.
      // By default, Android Studio creates a manifest for your main source
      // set in the src/main/ directory.
      manifest.srcFile("other/AndroidManifest.xml")
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying the
      // configuration below for the androidTest source set, Gradle looks for Java
      // sources only in the src/tests/java/ directory.
      setRoot("src/tests")
      ...
    }
  }
}
...

Cómo realizar compilaciones con conjuntos de fuentes

Puedes usar los directorios de conjuntos de fuentes para contener el código y los recursos que deseas empaquetar solo con determinadas configuraciones. Por ejemplo, si compilas la variante de compilación "demoDebug", que es el producto combinado de un tipo de producto de "demostración" y el tipo de compilación de "depuración", Gradle busca en esos directorios y les da la siguiente prioridad:

  1. src/demoDebug/ (conjunto de fuentes de variante de compilación)
  2. src/debug/ (conjunto de fuentes de tipo de compilación)
  3. src/demo/ (conjunto de fuentes de variante de producto)
  4. src/main/ (conjunto de orígenes principal)

Nota: Si combinas variantes de productos, la prioridad entre ellas se determina por la dimensión de variante a la que pertenecen. Cuando se listan la dimensión de variantes con la propiedad android.flavorDimensions, las variantes de productos que pertenecen a la primera dimensión que incluyes en la lista tienen mayor prioridad que aquellas que pertenecen a la segunda dimensión, y así sucesivamente. Además, los conjuntos de fuentes que creas para las combinaciones de tipos de productos tienen una prioridad superior con respecto a los conjuntos de fuentes que pertenecen a cada tipo de producto en particular.

El orden indicado determina el conjunto de fuentes que tiene prioridad más alta cuando Gradle combina código y recursos. Debido a que es posible que el directorio de conjunto de orígenes demoDebug/ contenga archivos específicos de esa variante de compilación, si demoDebug/ incluye un archivo que también se define en debug/, Gradle usa el archivo en el conjunto de orígenes demoDebug/. De manera similar, Gradle otorga a los archivos de los conjuntos de fuentes de tipo de compilación y tipo de producto una prioridad más alta con respecto a los mismos archivos en main/. Gradle tiene en cuenta este orden de prioridad al aplicar las siguientes reglas de compilación:

  • Todo el código fuente de los directorios java/ se compila en conjunto para generar un solo resultado.

    Nota: Para una variante determinada, Gradle genera un error de compilación si encuentra dos o más directorios de conjuntos de orígenes que hayan definido la misma clase Java. Por ejemplo, al compilar una app de depuración, no puedes definir src/debug/Utility.java y src/main/Utility.java a la vez, ya que Gradle realiza búsquedas en estos dos directorios durante el proceso de compilación y genera un error de "clase duplicada". Si deseas tener diferentes versiones de Utility.java para distintos tipos de compilación, puedes hacer que cada tipo de compilación defina su propia versión del archivo y no la incluya en el conjunto de orígenes main/.

  • Los manifiestos se fusionan en un solo archivo. La prioridad sigue el mismo orden que el de la lista anterior. Es decir, la configuración de manifiesto para un tipo de compilación anula la configuración de manifiesto para un tipo de producto, y así sucesivamente. Para obtener más información, lee documentación sobre la fusión de manifiestos.
  • De manera similar, se fusionan juntos los archivos de los directorios values/. Si dos archivos comparten el mismo nombre (por ejemplo, dos archivos strings.xml), se da el mismo orden de prioridad que el de la lista anterior. Es decir, los valores definidos en un archivo del conjunto de fuentes de tipo de compilación anulan los valores definidos en el mismo archivo de un tipo de producto, y así sucesivamente.
  • Los recursos de los directorios res/ y asset/ se empaquetan juntos. Si hay recursos con el mismo nombre definidos en dos o más conjuntos de fuentes, se les da prioridad en el mismo orden que el de la lista anterior.
  • Por último, al compilar la app, Gradle otorga la prioridad más baja a los recursos y manifiestos incluidos con las dependencias del módulo de biblioteca.

Cómo declarar dependencias

Además, puedes configurar una dependencia para una variante de compilación o un conjunto de orígenes de prueba específicos asignando prefijos al nombre de la variante de compilación o del conjunto de orígenes de prueba antes de la palabra clave de configuración Implementation, como se muestra en el siguiente ejemplo.

Groovy

dependencies {
    // Adds the local "mylibrary" module as a dependency to the "free" flavor.
    freeImplementation project(":mylibrary")

    // Adds a remote binary dependency only for local tests.
    testImplementation 'junit:junit:4.12'

    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
}

Kotlin

dependencies {
    // Adds the local "mylibrary" module as a dependency to the "free" flavor.
    freeImplementation(project(":mylibrary"))

    // Adds a remote binary dependency only for local tests.
    testImplementation("junit:junit:4.12")

    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation("com.android.support.test.espresso:espresso-core:3.0.2")
}

Para obtener más información, consulta Cómo agregar dependencias de compilación.

Cómo configurar ajustes de firma

Gradle no firma el APK o AAB de tu compilación de lanzamiento, a menos que definas explícitamente una configuración de firma para esa compilación. Si aún no tienes una clave de firma, consulta cómo generar una clave de carga y un almacén de claves con Android Studio.

Para configurar de forma manual los ajustes de firma de tu tipo de compilación de lanzamiento mediante configuraciones de compilación de Gradle, haz lo siguiente:

  1. Crea un almacén de claves. Un almacén de claves es un archivo binario que contiene un conjunto de claves privadas. Debes conservar el almacén de claves en un lugar seguro y protegido.
  2. Crea una clave privada. Una clave privada se usa a fin de firmar tu app para su distribución y nunca se incluye con la app ni se divulga a terceros no autorizados.
  3. Agrega la configuración de firma al archivo build.gradle del nivel del módulo:

    Groovy

    ...
    android {
        ...
        defaultConfig {...}
        signingConfigs {
            release {
                storeFile file("myreleasekey.keystore")
                storePassword "password"
                keyAlias "MyReleaseKey"
                keyPassword "password"
            }
        }
        buildTypes {
            release {
                ...
                signingConfig signingConfigs.release
            }
        }
    }

    Kotlin

    ...
    android {
        ...
        defaultConfig {...}
        signingConfigs {
            create("release") {
                storeFile = file("myreleasekey.keystore")
                storePassword = "password"
                keyAlias = "MyReleaseKey"
                keyPassword = "password"
            }
        }
        buildTypes {
            getByName("release") {
                ...
                signingConfig = signingConfigs.getByName("release")
            }
        }
    }

Nota: No es una buena práctica de seguridad incluir las contraseñas para tu clave de lanzamiento y almacén de claves dentro del archivo de compilación. Como alternativa, puedes configurar el archivo de compilación para que obtenga estas contraseñas de variables de entorno o que el proceso de compilación te solicite estas contraseñas.

Para obtener estas contraseñas desde variables de entorno, usa el siguiente código:

storePassword System.getenv("KSTOREPWD")
keyPassword System.getenv("KEYPWD")

Para que el proceso de compilación te solicite estas contraseñas si invocas la compilación desde la línea de comandos, usa el siguiente código:

storePassword System.console().readLine("\nKeystore password: ")
keyPassword System.console().readLine("\nKey password: ")

Luego de completar este proceso, puedes distribuir tu app y publicarla en Google Play.

Advertencia: Conserva tu almacén de claves y tu clave privada en un lugar seguro y protegido, y asegúrate de contar con copias de seguridad protegidas de ellos. Si usas la firma de apps de Play y pierdes tu clave de carga, puedes solicitar un restablecimiento mediante Play Console. Si publicas una app sin la firma de apps de Play (para las apps que se crearon antes de agosto de 2021) y pierdes la clave de firma de la app, no podrás publicar actualizaciones para tu app, ya que siempre deberás firmar todas sus versiones con la misma clave

Cómo firmar apps para Wear OS

Cuando publiques apps para Wear OS, deberás firmar el APK del reloj y opcionalmente el del teléfono. Puedes obtener más información para empaquetar y firmar apps para Wear OS en Cómo empaquetar y distribuir apps para Wear.