Skip to content

Most visited

Recently visited

navigation

빌드 변형 구성

이 페이지는 빌드 개요 구성을 토대로 하며, 단일 프로젝트에서 다양한 버전의 앱을 생성하기 위해 빌드 변형을 구성하는 방법과 종속성 및 서명 구성을 올바로 관리하는 방법을 보여줍니다.

빌드 변형은 여러분이 빌드할 수 있는 다양한 버전의 앱을 나타냅니다. 예를 들어, 콘텐츠가 제한된 무료 버전의 앱을 빌드하고, 더 많은 콘텐츠가 포함된 유료 버전의 앱을 빌드할 수 있습니다. 또한 API 레벨이나 기타 기기 변화에 따라 다양한 기기에 맞게 다양한 버전의 앱을 빌드할 수도 있습니다. 그러나, 기기 ABI나 화면 밀도에 따라 다양한 버전을 빌드하려는 경우에는 그 대신 APK 분할을 사용합니다.

빌드 변형은 Gradle이 특정 규칙 세트를 사용하여 빌드 유형과 제품 버전에 구성된 설정, 코드 및 리소스를 조합한 결과입니다. 여러분이 빌드 변형을 직접 구성하는 것은 아니며, 이를 형성하는 빌드 유형과 제품 버전을 구성하는 것입니다.

예를 들어, "데모" 제품 버전에서는 다양한 기능과 기기 요구사항을 지정할 수 있는 반면(예: 사용자설정 소스 코드, 리소스 및 최소 API 레벨), "디버그" 빌드 유형에서는 다양한 빌드 및 패키징 설정을 적용할 수 있습니다(예: 디버그 옵션 및 서명 키). 결과 빌드 변형은 "demoDebug" 버전의 앱이며 여기에는 "데모" 제품 버전, "디버그" 빌드 유형 및 main/ 소스 세트에 포함된 구성 및 리소스의 조합이 포함됩니다.

빌드 유형 구성

모듈 레벨 build.gradle 파일의 android {} 블록 내에 빌드 유형을 생성하고 구성할 수 있습니다. 여러분이 새 모듈을 생성하면 Android Studio가 여러분을 대신하여 디버그 및 릴리스 빌드 유형을 자동으로 생성합니다. 디버그 빌드 유형이 빌드 구성 파일에 나타나지 않더라도, Android Studio는 debuggable true로 이 빌드 유형을 구성합니다. 따라서 보안 Android 기기에서 앱을 디버깅할 수 있으며 일반 디버그 키스토어로 APK 서명을 구성합니다.

특정 설정을 추가하거나 변경하려는 경우 이 디버그 빌드 유형을 자신의 구성에 추가할 수 있습니다. 다음 샘플에서는 디버그 빌드 유형에 대해 applicationIdSuffix를 지정하고, 디버그 빌드 유형의 설정을 사용하여 초기화된 "jnidebug" 빌드 유형을 구성합니다.

android {
    ...
    defaultConfig {...}
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        debug {
            applicationIdSuffix ".debug"
        }

        /**
         * The 'initWith' property allows you to copy configurations from other build types,
         * so you don't have to configure one from the beginning. You can then configure
         * just the settings you want to change. The following line initializes
         * 'jnidebug' using the debug build type, and changes only the
         * applicationIdSuffix and versionNameSuffix settings.
         */

        jnidebug {

            // This copies the debuggable attribute and debug signing configurations.
            initWith debug

            applicationIdSuffix ".jnidebug"
            jniDebuggable true
        }
    }
}

참고: 빌드 구성 파일을 변경하면 Android Studio가 프로젝트를 새 구성으로 동기화하도록 요청합니다. 프로젝트를 동기화하려면, 변경을 수행하자마자 바로 나타나는 알림 막대에서 Sync Now를 클릭하거나 또는 툴바에서 Sync Project 아이콘 을 클릭합니다. Android Studio에서 구성 오류가 발견되면, 문제가 무엇인지 설명해주는 Messages 창이 나타납니다.

빌드 유형에서 구성할 수 있는 모든 속성에 대해 자세히 알아보려면 빌드 유형 DSL 참조를 읽어보세요.

제품 버전 구성

제품 버전을 생성하는 것은 빌드 유형을 생성하는 것과 유사하며, 제품 버전을 productFlavors {} 블록에 추가하고 원하는 설정을 구성하면 됩니다. 제품 버전은 defaultConfig와 동일한 속성을 지원합니다. 그 이유는 defaultConfig가 실제로 ProductFlavor 클래스에 속해 있기 때문입니다. 즉, defaultConfig {} 블록에 있는 모든 버전에 대해 기본 구성을 제공할 수 있으며, 각 버전은 applicationId와 같은 모든 기본값을 변경할 수 있습니다. 애플리케이션 ID에 대한 자세한 내용은 애플리케이션 ID 설정을 참조하세요.

참고: 그래도 여전히 main/ 매니페스트 파일에 있는 package 특성을 사용하여 패키지 이름을 지정해야 합니다. 또한 소스 코드에서 해당 패키지 이름을 사용하여 R 클래스를 참조하거나 상대적 액티비티나 서비스 등록을 확인해야 합니다. 이렇게 하면 소스 코드를 변경할 필요 없이 applicationId를 사용하여 각 제품 버전에 패키징 및 배포용 고유 ID를 제공할 수 있습니다.

다음 코드 샘플을 실행하면 자체적인 applicationIdSuffix versionNameSuffix를 제공하는 "demo" 및 "full" 제품 버전이 생성됩니다.

android {
    ...
    defaultConfig {...}
    buildTypes {...}
    productFlavors {
        demo {
            applicationIdSuffix ".demo"
            versionNameSuffix "-demo"
        }
        full {
            applicationIdSuffix ".full"
            versionNameSuffix "-full"
        }
    }
}

참고: Google Play에서 다중 APK 지원을 사용하여 앱을 배포하려면, 모든 변형에 동일한 applicationId 값을 할당하고 각 변형에 다른 versionCode를 부여합니다. 다양한 앱 변형을 별도의 앱으로 Google Play에 배포하려면, 각 변형에 다른 applicationId를 할당해야 합니다.

제품 버전을 생성하고 구성한 후, 알림 막대에서 Sync Now를 클릭합니다. 동기화가 완료되면 Gradle은 빌드 유형과 제품 버전에 따라 자동으로 빌드 변형을 생성하고 <product-flavor><Build-Type>에 따라 빌드 변형의 이름을 지정합니다. 예를 들어, '데모' 및 '풀' 제품 버전을 생성하고 기본 '디버그' 및 '릴리스' 빌드 유형을 유지하면 Gradle은 다음과 같은 빌드 변형을 만듭니다.

빌드 변형을 여러분이 빌드하고 실행하고자 하는 것으로 변경할 수 있습니다. Build > Select Build Variant로 이동하여 드롭다운 메뉴에서 빌드 변형을 선택합니다. 그러나 고유한 기능과 리소스를 가진 빌드 변형의 사용자 지정을 시작하려면, 소스 세트를 생성하고 관리하는 방법을 알아야 합니다.

여러 제품 버전의 조합

여러 제품 버전의 구성을 조합하고 싶을 때도 있을 것입니다. 예를 들어, API 레벨을 기준으로 "full" 및 "demo" 제품 버전에 대해 서로 다른 구성을 생성할 수도 있습니다. 이 작업을 위해, Gradle용 Android 플러그인을 사용하면 버전 차원이라는 제품 버전 그룹을 생성할 수 있습니다. 앱을 빌드할 때 Gradle은 빌드 유형 구성과 함께 최종 빌드 변형을 생성하기 위해 개발자가 정의하는 각 버전 차원에서 제품 버전 구성을 조합합니다. Gradle은 동일한 버전 차원에 속한 제품 버전을 조합하지 않습니다.

팁: ABI와 화면 밀도를 기반으로 다양한 버전의 앱을 만들려면 제품 버전을 사용하는 대신 APK 분할 구성을 수행해야 합니다.

다음 코드 샘플에서는 flavorDimensions 속성을 사용하여 "full" 및 "demo" 제품 버전을 그룹화하는 "mode" 버전 차원과 API 레벨을 기반으로 제품 버전 구성을 그룹화하는 "api" 버전 차원을 생성합니다.

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig {} block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion '24'
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion '23'
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion '21'
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Gradle이 생성하는 빌드 변형의 개수는 각 버전 차원에 있는 버전의 수와 개발자가 구성하는 빌드 유형의 수를 곱한 값과 같습니다. Gradle이 각 빌드 변형 또는 해당 APK의 이름을 지정하면 우선순위가 높은 버전 차원에 속한 제품 버전이 먼저 나타난 다음에 우선순위가 낮은 차원의 제품 버전, 빌드 유형이 차례대로 나타납니다. Gradle은 위에서 예로 든 빌드 구성을 사용하여 다음과 같은 이름 지정 체계로 총 12개의 빌드 변형을 생성합니다.

빌드 변형: [minApi24, minApi23, minApi21][Demo, Full][Debug, Release]
해당 APK: app-[minApi24, minApi23, minApi21]-[demo, full]-[debug, release].apk
예를 들어,
빌드 변형: minApi24DemoDebug
해당 APK: app-minApi24-demo-debug.apk

각각의 개별 제품 버전 및 빌드 변형에 대해 생성할 수 있는 소스 세트 디렉토리 외에, 제품 버전의 각 조합에 대한 소스 세트 디렉토리도 만들 수 있습니다. 예를 들어 자바 소스를 생성하여 src/demoMinApi24/java/ 디렉토리에 추가할 수 있고, Gradle은 이러한 두 제품 버전을 조합한 변형을 빌드할 때만 자바 소스를 사용합니다. 제품 버전 조합을 위해 생성하는 소스 세트의 우선순위가 각각의 개별 제품 버전에 속한 소스 세트보다 높습니다. 소스 세트와 Gradle이 리소스를 병합하는 방식에 대해 자세히 알아보려면 소스 세트 생성 방법에 대한 섹션을 읽어보세요.

필터 변형

Gradle은 개발자가 구성하는 제품 버전과 빌드 유형의 가능한 모든 조합을 위한 빌드 변형을 생성합니다. 하지만 필요하지 않거나 프로젝트의 컨텍스트를 고려할 때 이치에 닿지 않는 특정 빌드 변형이 있을 수 있습니다. 모듈 레벨 build.gradle 파일에 변형 필터를 생성하여 특정 빌드 변형 구성을 제거할 수 있습니다.

이전 섹션에서 예시한 빌드 구성을 사용할 때 앱의 데모 버전에 대해 API 레벨 23 이상만 지원할 계획이라고 가정해 봅시다. variantFilter {} 블록을 사용하여 "minApi21" 제품 버전과 "demo" 제품 버전을 조합하는 빌드 변형 구성을 전부 걸러낼 수 있습니다.

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

빌드 구성에 변형 필터를 추가하고 알림 표시줄에서 Sync Now를 클릭하면 Gradle은 개발자가 지정하는 조건을 충족하는 빌드 변형을 모두 무시하므로, 메뉴 모음에서 Build > Select Build Variant를 클릭하거나 도구 창 모음에서 Build Variants를 클릭하면 이러한 빌드 변형이 더 이상 드롭다운 메뉴에 나타나지 않습니다.

소스 세트 생성

기본적으로 Android Studio는 모든 빌드 변형 간에 여러분이 공유하려는 모든 것에 대해 main/ 소스 세트 및 디렉토리를 생성합니다. 그러나 특정 빌드 유형, 제품 버전(그리고 버전 차원을 사용할 때는 제품 버전의 조합) 및 빌드 변형에 대해 Gradle이 컴파일하고 패키징하는 파일을 정확히 제어하기 위해 새로운 소스 세트를 생성할 수 있습니다. 예를 들어, 기본적인 기능은 main/ 소스 세트에 정의하고, 제품 버전 소스 세트를 사용하여 다양한 클라이언트에 대해 앱 브랜드를 변경하거나 디버그 빌드 유형을 사용하는 빌드 변형에 대해서만 특별 권한과 로깅 기능을 포함할 수 있습니다.

Gradle은 여러분이 main/ 소스 세트와 유사한 방식으로 소스 세트 파일과 디렉토리를 구성할 것으로 예상합니다. 예를 들어, Gradle은 "디버그" 빌드 유형 전용의 자바 클래스 파일이 src/debug/java/ 디렉토리에 있을 것으로 예상합니다.

Gradle용 Android 플러그인은 각 빌드 유형, 제품 버전 및 빌드 변형에 대한 파일 구성 방법을 보여주는 유용한 Gradle 작업을 제공합니다. 예를 들어, 다음 보고서 섹션은 Gradle이 "디버그" 빌드 유형에 대해 특정 파일을 찾을 것으로 예상되는 위치를 설명합니다.

------------------------------------------------------------
Project :app
------------------------------------------------------------

...

debug
----
Compile configuration: compile
build.gradle name: android.sourceSets.debug
Java sources: [app/src/debug/java]
Manifest file: app/src/debug/AndroidManifest.xml
Android resources: [app/src/debug/res]
Assets: [app/src/debug/assets]
AIDL sources: [app/src/debug/aidl]
RenderScript sources: [app/src/debug/rs]
JNI sources: [app/src/debug/jni]
JNI libraries: [app/src/debug/jniLibs]
Java-style resources: [app/src/debug/resources]

여러분의 빌드 구성에 대해 이 보고서를 생성하고 보려면, 다음 단계를 진행하세요.

  1. IDE 창의 오른쪽에서 Gradle 클릭합니다.
  2. MyApplication > Tasks > android로 이동하여 sourceSets을 두 번 클릭합니다.
  3. 보고서를 보려면 IDE 창의 아래쪽에서 Gradle Console 클릭하세요.

참고: 이 보고서는 또한 앱에 테스트를 실행하는 데 사용할 파일의 소스 세트를 구성하는 방법도 보여줍니다(예: test/ androidTest/테스트 소스 세트).

새 빌드 변형을 생성할 때 Android Studio가 소스 세트 디렉토리를 자동으로 생성하지는 않지만, 도움이 되는 몇 가지 옵션을 제공합니다. 예를 들어, "디버그" 빌드 유형에 대해 java/ 디렉토리만 생성하는 방법은 다음과 같습니다.

  1. Project 창을 열고 창 상단의 드롭다운 메뉴에서 Project 뷰를 선택합니다.
  2. MyProject/app/src/로 이동합니다.
  3. src 디렉토리를 마우스 오른쪽 버튼으로 클릭하고 New > Folder > Java Folder를 선택합니다.
  4. Target Source Set 옆의 드롭다운 메뉴에서 debug를 선택합니다.
  5. Finish를 클릭합니다.

Android Studio가 디버그 빌드 유형에 대해 소스 세트 디렉토리를 생성한 다음, 그 안에 java/ 디렉토리를 생성합니다. 또는 특정 빌드 변형에 대해 새 파일을 프로젝트에 추가할 때, Android Studio가 자동으로 디렉토리를 생성하도록 할 수 있습니다. 예를 들어, "디버그" 빌드 유형에 대해 Values XML 파일을 생성하려면:

  1. 동일한 Project 창에서 src 디렉토리를 마우스 오른쪽 버튼으로 클릭하고 New > XML > Values XML File을 선택합니다.
  2. XML 파일의 이름을 입력하거나 기본 이름을 유지합니다.
  3. Target Source Set 옆의 드롭다운 메뉴에서 debug를 선택합니다.
  4. Finish를 클릭합니다.

"디버그" 빌드 유형이 대상 소스 세트로 지정되었기 때문에, Android Studio는 XML 파일을 생성할 때 필요한 디렉토리를 자동으로 생성합니다. 결과 디렉토리 구조는 그림 2와 같아야 합니다.

그림 2. 디버그 빌드 유형에 대한 새 소스 세트 디렉토리.

또한 동일한 절차를 사용하여 제품 버전(예: src/demo/)과 빌드 변형(예: src/demoDebug/)에 대한 소스 세트 디렉토리를 생성할 수도 있습니다. 그 밖에도, 특정 빌드 변형을 대상으로 하는 테스트 소스 세트를 생성할 수 있습니다(예: src/androidTestDemoDebug/). 자세히 알아보려면 테스트 소스 세트로 이동하세요.

기본 소스 세트 구성 변경

Gradle이 예상하는 기본 소스 세트 파일 구조로 구성되지 않은 소스가 있는 경우에는 앞서 소스 세트 생성 섹션에서 설명한 것처럼 sourceSets {} 블록을 사용하여 Gradle이 소스 세트의 각 구성 요소에 대해 파일을 수집하는 위치를 변경할 수 있습니다. 파일의 위치를 변경할 필요는 없습니다. Gradle이 각 소스 세트 구성 요소에 대한 파일을 당연히 찾을 수 있을 것으로 예상하는 모듈 레벨 build.gradle 파일에 상대적인 경로를 Gradle에 제공하기만 하면 됩니다. 어떤 구성 요소를 구성할 수 있을지, 그리고 이러한 구성 요소를 여러 파일이나 디렉토리로 매핑할 수 있을지 알아보려면 Gradle DSL 참조용 Android 플러그인을 읽어보세요.

다음은 app/other/ 디렉토리의 소스를 main 소스 세트의 특정 구성 요소로 매핑하고 androidTest 소스 세트의 루트 디렉토리를 변경하는 코드 샘플입니다.

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // If you list multiple directories, Gradle uses all of them to collect
      // sources. Because Gradle gives these directories equal priority, if
      // you define the same resource in more than one directory, you get an
      // error when merging resources. The default directory is 'src/main/res'.
      res.srcDirs = ['other/res1', 'other/res2']

      // Note: You should avoid specifying a directory which is a parent to one
      // or more other directories you specify. For example, avoid the following:
      // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
      // You should specify either only the root 'other/res1' directory, or only the
      // nested 'other/res1/layouts' and 'other/res1/strings' directories.

      // For each source set, you can specify only one Android manifest.
      // By default, Android Studio creates a manifest for your main source
      // set in the src/main/ directory.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying the
      // configuration below for the androidTest source set, Gradle looks for Java
      // sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

소스 세트로 빌드

소스 세트 디렉토리를 사용하여 특정 구성으로만 패키징하려는 코드와 리소스를 포함할 수 있습니다. 예를 들어, "데모" 제품 버전과 "디버그" 빌드 유형의 교차 제품(crossproduct)인 "demoDebug" 빌드 변형을 빌드하는 경우, Gradle은 아래의 디렉토리를 찾아서 다음과 같이 우선순위를 부여합니다.

  1. src/demoDebug/ (빌드 변형 소스 세트)
  2. src/debug/ (빌드 유형 소스 세트)
  3. src/demo/ (제품 버전 소스 세트)
  4. src/main/ (메인 소스 세트)

참고: 여러 제품 버전을 조합할 경우 제품 버전 간의 우선순위는 제품 버전이 속한 버전 차원에 따라 결정됩니다. android.flavorDimensions 속성을 가진 버전 차원을 나열할 때, 맨 처음에 나열하는 버전 차원에 속한 제품 버전이 두 번째 버전 차원에 속한 제품 버전보다 우선순위가 높고, 그 이후로도 마찬가지 방식으로 적용됩니다. 또한, 제품 버전의 조합을 위해 생성하는 소스 세트의 우선순위가 각각의 개별 제품 버전에 속한 소스 세트보다 높습니다.

위에 나열된 순서는 Gradle이 코드와 리소스를 조합할 때 어떤 소스 세트의 우선순위가 더 높은지를 결정합니다. demoDebug/ 소스 세트 디렉토리에는 해당 빌드 변형에 특정한 파일이 포함될 가능성이 높으므로, debug/에 정의된 파일이 demoDebug/에도 포함된 경우, Gradle은 demoDebug/ 소스 세트에 있는 파일을 사용합니다. 마찬가지로, Gradle은 main/에 있는 파일보다 빌드 유형 및 제품 버전 소스 세트에 있는 동일한 파일에 더 높은 우선순위를 부여합니다. Gradle은 다음과 같은 빌드 규칙을 적용할 때 이 우선순위를 고려합니다.

종속성 선언

다음 예에서는 다양한 종류의 직접 종속성을 app/ 모듈의 build.gradle 파일에 선언합니다.

android {...}
...
dependencies {
    // The 'compile' configuration tells Gradle to add the dependency to the
    // compilation classpath and include it in the final package.

    // Dependency on the "mylibrary" module from this project
    compile project(":mylibrary")

    // Remote binary dependency
    compile 'com.android.support:appcompat-v7:27.0.2'

    // Local binary dependency
    compile fileTree(dir: 'libs', include: ['*.jar'])
}

이러한 각 직접 종속성이 아래에 설명되어 있습니다.

모듈 종속성
compile project(':mylibrary') 줄은 "mylibrary"라는 로컬 Android 라이브러리 모듈을 종속성으로 선언하며, 앱을 빌드할 때 로컬 모듈을 컴파일하고 포함하도록 빌드 시스템에 요구합니다.
원격 바이너리 종속성
compile 'com.android.support:appcompat-v7:27.0.2' 줄은 JCenter 좌표를 지정하여 버전 27.0.2의 Android Support Library에 대한 종속성을 선언합니다. 기본적으로, Android Studio는 JCenter Repository를 최상위 빌드 파일에서 사용하도록 프로젝트를 구성합니다. 프로젝트를 빌드 구성 파일과 동기화할 때 Gradle은 자동으로 JCenter에서 종속성을 가져옵니다. 또는, SDK Manager를 사용하여 특정 종속성을 다운로드하고 설치할 수 있습니다.
로컬 바이너리 종속성
compile fileTree(dir: 'libs', include: ['*.jar']) 줄은 app/libs/ 디렉토리 내의 모든 JAR 파일을 컴파일 클래스 경로와 최종 앱 패키지에 포함하도록 빌드 시스템에 알립니다. 로컬 바이너리 종속성을 요구하는 모듈이 있는 경우, 이 종속성에 대한 JAR 파일을 프로젝트 내의 <moduleName>/libs에 복사합니다.

모듈의 직접 종속성 중 일부는 모듈의 이행성 종속성이라고 하는 자체 종속성이 있을 수 있습니다. 각 이행성 종속성을 수동으로 선언할 필요가 없으며, Gradle이 이 종속성을 자동으로 수집하고 추가합니다. Gradle용 Android 플러그인은 각 빌드 변형 및 테스트 소스 세트에 대해 종속성 트리를 생성할 수 있는 유용한 Gradle 작업을 제공하므로, 모듈의 직접 종속성 및 이행성 종속성을 쉽게 시각화할 수 있습니다. 이 보고서를 생성하려면, 다음 단계를 진행하세요.

  1. IDE 창의 오른쪽에서 Gradle 클릭합니다.
  2. MyApplication > Tasks > android로 이동하여 androidDependencies를 두 번 클릭합니다.
  3. 보고서를 보려면 IDE 창의 아래쪽에서 Gradle Console 클릭하세요.

다음 샘플은 디버그 빌드 변형에 대한 종속성 트리를 보여주며, 이전 예시의 로컬 모듈 종속성과 원격 종속성을 포함합니다.

Executing tasks: [androidDependencies]
:app:androidDependencies
debug
/**
 * Both the library module dependency and remote binary dependency are listed
 * with their transitive dependencies.
 */
+--- MyApp:mylibrary:unspecified
|    \--- com.android.support:appcompat-v7:27.0.2
|         +--- com.android.support:animated-vector-drawable:27.0.2
|         |    \--- com.android.support:support-vector-drawable:27.0.2
|         |         \--- com.android.support:support-v4:27.0.2
|         |              \--- LOCAL: internal_impl-27.0.2.jar
|         +--- com.android.support:support-v4:27.0.2
|         |    \--- LOCAL: internal_impl-27.0.2.jar
|         \--- com.android.support:support-vector-drawable:27.0.2
|              \--- com.android.support:support-v4:27.0.2
|                   \--- LOCAL: internal_impl-27.0.2.jar
\--- com.android.support:appcompat-v7:27.0.2
     +--- com.android.support:animated-vector-drawable:27.0.2
     |    \--- com.android.support:support-vector-drawable:27.0.2
     |         \--- com.android.support:support-v4:27.0.2
     |              \--- LOCAL: internal_impl-27.0.2.jar
     +--- com.android.support:support-v4:27.0.2
     |    \--- LOCAL: internal_impl-27.0.2.jar
     \--- com.android.support:support-vector-drawable:27.0.2
          \--- com.android.support:support-v4:27.0.2
               \--- LOCAL: internal_impl-27.0.2.jar
...

Gradle에서 종속성 관리에 대한 자세한 내용은, Gradle 사용자 가이드의 종속성 관리 기본 사항을 참조하세요.

종속성 구성

종속성을 사용하는 방법과 시기를 Gradle에 알리기 위해 특정한 구성 키워드를 사용할 수 있습니다(예: 이전 예시의 compile 키워드). 아래에서는 종속성 구성에 사용할 수 있는 몇 가지 키워드를 설명합니다.

compile
컴파일 시 종속성을 지정합니다. Gradle은 이 구성이 있는 종속성을 클래스 경로와 앱의 APK 모두에 추가합니다. 이는 기본 구성입니다.
apk
Gradle이 앱의 APK와 함께 패키징해야 하는 런타임 전용 종속성을 지정합니다. 이 구성은 JAR 바이너리 종속성과 함께 사용될 수 있지만, 다른 라이브러리 모듈 종속성이나 AAR 바이너리 종속성과는 사용될 수 없습니다.
provided
Gradle이 앱의 APK와 함께 패키징하지 않는 컴파일 시 종속성을 지정합니다. 따라서 런타임 중에 종속성이 불필요하면 APK의 크기를 줄일 수 있습니다. 이 구성은 JAR 바이너리 종속성과 함께 사용될 수 있지만, 다른 라이브러리 모듈 종속성이나 AAR 바이너리 종속성과는 사용될 수 없습니다.

또는 다음 샘플에 나오는 것처럼, 빌드 변형 또는 테스트 소스 세트의 이름을 구성 키워드에 적용하여 특정 빌드 변형 또는 테스트 소스 세트에 대한 종속성을 구성할 수 있습니다.

dependencies {
    ...
    // Adds specific library module dependencies as compile time dependencies
    // to the fullRelease and fullDebug build variants.
    fullReleaseCompile project(path: ':library', configuration: 'release')
    fullDebugCompile project(path: ':library', configuration: 'debug')

    // Adds a compile time dependency for local tests.
    testCompile 'junit:junit:4.12'

    // Adds a compile time dependency for the test APK.
    androidTestCompile 'com.android.support.test.espresso:espresso-core:2.2.2'
}

서명 설정 구성

릴리스 빌드의 서명 구성을 명시적으로 구성하지 않는 경우, Gradle은 이 빌드의 APK를 서명하지 않습니다. Android Studio를 사용하여 쉽게 릴리스 키를 만들고 릴리스 빌드 유형을 서명할 수 있습니다.

Gradle 빌드 구성을 사용하여 릴리스 빌드 유형의 서명 구성을 수동으로 구성하려면:

  1. 키스토어를 생성합니다. 키스토어는 개인 키 세트가 포함된 바이너리 파일입니다. 키스토어는 안전하고 보안이 유지되는 장소에 보관해야 합니다.
  2. 개인 키를 생성합니다. 개인 키는 개인이나 회사와 같이 앱으로 식별되는 엔티티를 나타냅니다.
  3. 서명 구성을 모듈 레벨 build.gradle 파일에 추가합니다.

    ...
    android {
        ...
        defaultConfig {...}
        signingConfigs {
            release {
                storeFile file("myreleasekey.keystore")
                storePassword "password"
                keyAlias "MyReleaseKey"
                keyPassword "password"
            }
        }
        buildTypes {
            release {
                ...
                signingConfig signingConfigs.release
            }
        }
    }
    

서명된 APK를 생성하려면, 메뉴 모음에서 Build > Generate Signed APK를 선택합니다. 이제 app/build/apk/app-release.apk의 패키지가 릴리스 키로 서명되었습니다.

참고: 릴리스 키와 키스토어의 암호를 빌드 파일 내에 포함하는 것은 보안에 좋지 않습니다. 대신 환경 변수에서 이러한 암호를 가져오도록 빌드 파일을 구성하거나 빌드 프로세스에서 이러한 암호를 입력하도록 메시지를 표시할 수 있습니다.

환경 변수에서 이러한 암호를 가져오려면:

storePassword System.getenv("KSTOREPWD")
keyPassword System.getenv("KEYPWD")

명령줄에서 빌드를 호출하는 경우, 빌드 프로세스에서 이러한 암호를 입력하도록 메시지를 표시하려면:

storePassword System.console().readLine("\nKeystore password: ")
keyPassword System.console().readLine("\nKey password: ")

이 프로세스를 완료한 후 앱을 배포하고 Google Play에 게시할 수 있습니다.

경고: 키스토어와 개인 키는 안전하고 보안된 장소에 보관하고 보안된 백업을 갖고 있어야 합니다. Google Play에 앱을 게시하고 앱에 서명한 개인 키를 분실하면 앱에 업데이트를 전혀 게시할 수 없게 됩니다. 항상 모든 앱 버전에서 같은 키로 서명해야 하기 때문입니다.

Android Wear 앱 서명

Android Wear 앱을 게시할 때는 핸드헬드 앱의 내부에 웨어러블 앱을 패키징합니다. 사용자가 웨어러블에서 직접 앱을 탐색, 설치할 수 없기 때문입니다. 두 앱은 모두 서명을 받아야 합니다. Android Wear 앱을 패키징하고 이 APK에 서명하는 방법에 대한 자세한 내용은 웨어러블 앱 패키징을 참조하세요.

This site uses cookies to store your preferences for site-specific language and display options.

Get the latest Android developer news and tips that will help you find success on Google Play.

* Required Fields

Hooray!

Follow Google Developers on WeChat

Browse this site in ?

You requested a page in , but your language preference for this site is .

Would you like to change your language preference and browse this site in ? If you want to change your language preference later, use the language menu at the bottom of each page.

This class requires API level or higher

This doc is hidden because your selected API level for the documentation is . You can change the documentation API level with the selector above the left navigation.

For more information about specifying the API level your app requires, read Supporting Different Platform Versions.

Take a short survey?
Help us improve the Android developer experience. (Dec 2017 Android Platform & Tools Survey)