빌드 변형 구성

이 페이지는 빌드 구성 개요를 토대로 하며, 단일 프로젝트에서 다양한 버전의 앱을 생성하기 위해 빌드 변형을 구성하는 방법과 종속 항목 및 서명 구성을 올바르게 관리하는 방법을 보여줍니다.

빌드 변형은 빌드할 수 있는 다른 버전의 앱을 나타냅니다. 예를 들어, 콘텐츠가 제한된 무료 버전의 앱을 빌드하고, 더 많은 콘텐츠가 포함된 유료 버전의 앱을 빌드할 수 있습니다. 또한, API 수준이나 기타 기기 변형에 따라 다양한 기기에 맞게 다른 버전의 앱을 빌드할 수도 있습니다.

빌드 변형은 Gradle이 특정 규칙 세트를 사용하여 빌드 유형과 제품 버전에 구성된 설정, 코드 및 리소스를 조합한 결과입니다. 개발자는 빌드 변형을 직접 구성하지 않으며 이를 형성하는 빌드 유형과 제품 버전을 구성합니다.

예를 들어, 'demo' 제품 버전에서는 다양한 기능과 기기 요구사항(예: 맞춤 소스 코드, 리소스 및 최소 API 수준)을 지정할 수 있는 반면, 'debug' 빌드 유형에서는 다양한 빌드 및 패키징 설정(예: 디버그 옵션 및 서명 키)을 적용할 수 있습니다. 결과 빌드 변형은 'demoDebug' 버전의 앱이며 여기에는 '데모' 제품 버전, '디버그' 빌드 유형 및 main/ 소스 세트에 포함된 구성 및 리소스의 조합이 포함됩니다.

빌드 유형 구성

모듈 레벨 build.gradle 파일의 android 블록 내에 빌드 유형을 생성하고 구성할 수 있습니다. 개발자가 새 모듈을 생성하면 Android 스튜디오에서 디버그 및 출시 빌드 유형을 자동으로 생성합니다. 디버그 빌드 유형이 빌드 구성 파일에 나타나지 않더라도, Android 스튜디오는 debuggable true로 이 빌드 유형을 구성합니다. 따라서 보안 Android 기기에서 앱을 디버그할 수 있으며 일반 디버그 키 저장소로 앱 서명을 구성합니다.

특정 설정을 추가하거나 변경하려면 디버그 빌드 유형을 구성에 추가하면 됩니다. 다음 샘플에서는 디버그 빌드 유형에 applicationIdSuffix를 지정하고, 디버그 빌드 유형의 설정을 사용하여 초기화된 'staging' 빌드 유형을 구성합니다.

Groovy

android {
    defaultConfig {
        manifestPlaceholders = [hostName:"www.example.com"]
        ...
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        debug {
            applicationIdSuffix ".debug"
            debuggable true
        }

        /**
         * The `initWith` property allows you to copy configurations from other build types,
         * then configure only the settings you want to change. This one copies the debug build
         * type, and then changes the manifest placeholder and application ID.
         */
        staging {
            initWith debug
            manifestPlaceholders = [hostName:"internal.example.com"]
            applicationIdSuffix ".debugStaging"
        }
    }
}

Kotlin

android {
    defaultConfig {
        manifestPlaceholders["hostName"] = "www.example.com"
        ...
    }
    buildTypes {
        getByName("release") {
            isMinifyEnabled = true
            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
        }

        getByName("debug") {
            applicationIdSuffix = ".debug"
            isDebuggable = true
        }

        /**
         * The `initWith` property allows you to copy configurations from other build types,
         * then configure only the settings you want to change. This one copies the debug build
         * type, and then changes the manifest placeholder and application ID.
         */
        create("staging") {
            initWith(getByName("debug"))
            manifestPlaceholders["hostName"] = "internal.example.com"
            applicationIdSuffix = ".debugStaging"
        }
    }
}

참고: 개발자가 빌드 구성 파일을 변경하면 Android 스튜디오는 프로젝트를 새 구성으로 동기화하도록 요청합니다. 프로젝트를 동기화하려면 변경사항이 생기자마자 바로 나타나는 알림바에서 Sync Now를 클릭하거나 툴바에서 Sync Project 를 클릭합니다. Android 스튜디오에서 구성 오류가 발견되면, 문제가 무엇인지 설명해주는 Messages 창이 나타납니다.

빌드 유형에서 구성할 수 있는 모든 속성에 관해 자세히 알아보려면 BuildType DSL 참조를 읽어보세요.

제품 버전 구성

제품 버전 생성은 빌드 유형 생성과 비슷합니다. 즉, 제품 버전을 빌드 구성의 productFlavors 블록에 추가한 다음 원하는 설정을 포함하면 됩니다. 제품 버전은 defaultConfig와 동일한 속성을 지원합니다. 그 이유는 defaultConfig가 실제로 ProductFlavor 클래스에 속해 있기 때문입니다. 즉, defaultConfig 블록에 모든 버전의 기본 구성을 제공할 수 있으며, 각 버전은 applicationId와 같은 모든 기본값을 변경할 수 있습니다. 애플리케이션 ID에 관한 자세한 내용은 애플리케이션 ID 설정을 참고하세요.

참고: 하지만 패키지 이름은 계속해서 main/ 매니페스트 파일에 있는 package 속성을 사용하여 지정해야 합니다. 또한, R 클래스를 참조하거나 관련 활동 또는 서비스를 등록하기 위해 소스 코드에서 패키지 이름을 사용해야 합니다. 이렇게 하면 소스 코드를 변경할 필요 없이 applicationId를 사용하여 각 제품 버전에 패키징 및 배포용 고유 ID를 제공할 수 있습니다.

모든 버전은 명명된 버전 차원에 속해 있어야 하며, 여기서 버전 차원은 제품 버전의 집합입니다. 개발자는 모든 버전을 버전 차원에 할당해야 하며, 그렇게 하지 않으면 다음과 같은 빌드 오류가 발생합니다. 특정 모듈에서 하나의 버전 차원만 지정한다면, Android Gradle 플러그인은 자동으로 모듈의 모든 버전을 동일한 버전 차원에 할당합니다.

  Error:All flavors must now belong to a named flavor dimension.
  The flavor 'flavor_name' is not assigned to a flavor dimension.

다음 코드 샘플에서는 'version'이라는 버전 차원을 생성하고 제품 버전 'demo'와 'full'을 추가합니다. 이러한 버전에서는 자체적인 applicationIdSuffixversionNameSuffix를 제공합니다.

Groovy

android {
    ...
    defaultConfig {...}
    buildTypes {
        debug{...}
        release{...}
    }
    // Specifies one flavor dimension.
    flavorDimensions "version"
    productFlavors {
        demo {
            // Assigns this product flavor to the "version" flavor dimension.
            // If you are using only one dimension, this property is optional,
            // and the plugin automatically assigns all the module's flavors to
            // that dimension.
            dimension "version"
            applicationIdSuffix ".demo"
            versionNameSuffix "-demo"
        }
        full {
            dimension "version"
            applicationIdSuffix ".full"
            versionNameSuffix "-full"
        }
    }
}

Kotlin

android {
    ...
    defaultConfig {...}
    buildTypes {
        getByName("debug"){...}
        getByName("release"){...}
    }
    // Specifies one flavor dimension.
    flavorDimensions "version"
    productFlavors {
        create("demo") {
            // Assigns this product flavor to the "version" flavor dimension.
            // If you are using only one dimension, this property is optional,
            // and the plugin automatically assigns all the module's flavors to
            // that dimension.
            dimension = "version"
            applicationIdSuffix = ".demo"
            versionNameSuffix = "-demo"
        }
        create("full") {
            dimension = "version"
            applicationIdSuffix = ".full"
            versionNameSuffix = "-full"
        }
    }
}

참고: Google Play에서 APK를 사용하여 배포하는 기존 앱(2021년 8월 이전에 생성됨)의 경우 Google Play에서 다중 APK 지원을 사용하여 앱을 배포하려면 모든 변형에 동일한 applicationId 값을 할당하고 각 변형에 서로 다른 versionCode를 부여해야 합니다. 다양한 앱 변형을 별도의 앱으로 Google Play에 배포하려면, 각 변형에 다른 applicationId를 할당해야 합니다.

제품 버전을 생성하고 구성한 후, 알림바에서 Sync Now를 클릭합니다. 동기화가 완료되면 Gradle은 빌드 유형과 제품 버전에 따라 자동으로 빌드 변형을 생성하고 <product-flavor><Build-Type>에 따라 빌드 변형의 이름을 지정합니다. 예를 들어, 'demo' 및 'full' 제품 버전을 생성하고 기본 'debug' 및 'release' 빌드 유형을 유지하면 Gradle은 다음과 같은 빌드 변형을 만듭니다.

  • demoDebug
  • demoRelease
  • fullDebug
  • fullRelease

빌드 변형은 빌드 및 실행하고자 하는 변형으로 변경할 수 있습니다. Build > Select Build Variant로 이동하여 드롭다운 메뉴에서 원하는 변형을 선택합니다. 그러나 고유한 기능과 리소스를 사용하는 각 빌드 변형의 맞춤설정을 시작하려면 소스 세트를 생성하고 관리하는 방법을 알아야 합니다.

빌드 변형을 위해 애플리케이션 ID 변경

앱의 APK 또는 AAB를 빌드할 때 빌드 도구는 build.gradle 파일의 defaultConfig 블록에 정의된 애플리케이션 ID로 앱에 태그를 지정합니다(아래 참고). 그러나, Google Play 스토어에 다양한 앱 버전(예: 'free' 및 'pro' 버전)이 별도의 목록으로 표시되도록 하려면 애플리케이션 ID가 서로 다른 별개의 빌드 변형을 만들어야 합니다. 이 경우에는 빌드 변형마다 별도의 제품 버전을 정의해야 합니다. productFlavors 블록 내부의 각 버전에 applicationId 속성을 재정의하거나, 아래와 같이 applicationIdSuffix를 사용하여 기본 애플리케이션 ID에 세그먼트를 추가할 수 있습니다.

Groovy

android {
    defaultConfig {
        applicationId "com.example.myapp"
    }
    productFlavors {
        free {
            applicationIdSuffix ".free"
        }
        pro {
            applicationIdSuffix ".pro"
        }
    }
}

Kotlin

android {
    defaultConfig {
        applicationId = "com.example.myapp"
    }
    productFlavors {
        create("free") {
            applicationIdSuffix = ".free"
        }
        create("pro") {
            applicationIdSuffix = ".pro"
        }
    }
}
이렇게 하면 'free' 제품 버전의 애플리케이션 ID는 'com.example.myapp.free'가 됩니다. 아래와 같이 빌드 유형에 따라 applicationIdSuffix를 사용하여 세그먼트를 추가할 수도 있습니다.

Groovy

android {
    ...
    buildTypes {
        debug {
            applicationIdSuffix ".debug"
        }
    }
}

Kotlin

android {
    ...
    buildTypes {
        getByName("debug") {
            applicationIdSuffix = ".debug"
        }
    }
}
Gradle에서는 제품 버전 뒤에 빌드 유형 구성을 적용하므로 'free debug' 빌드 변형의 애플리케이션 ID는 'com.example.myapp.free.debug'입니다. 이는 두 개의 앱이 동일한 애플리케이션 ID를 가질 수 없으므로 하나의 기기에 디버그 빌드와 출시 빌드를 모두 두려고 할 때 유용합니다. Google Play에서 APK를 사용하여 배포하는 기존 앱의 경우(2021년 8월 이전에 생성된 앱) 동일한 앱 등록정보를 사용하여 각각 다른 기기 설정(예: API 수준)을 타겟팅하는 여러 APK를 배포하려면 각 빌드 변형에 같은 애플리케이션 ID를 사용하고 각 APK에 다른 versionCode를 부여해야 합니다. 자세한 내용은 다중 APK 지원을 참고하세요. AAB를 사용하는 게시는 기본적으로 단일 버전 코드와 애플리케이션 ID를 사용하는 단일 아티팩트를 사용하므로 영향을 받지 않습니다.

주의: build.gradle 파일에서 applicationId 속성을 정의하지 않으면 빌드 도구는 이전 SDK 도구 호환성을 위해 AndroidManifest.xml 파일의 패키지 이름을 애플리케이션 ID로 사용합니다. 이 경우 패키지 이름을 리팩터링하면 애플리케이션 ID도 변경됩니다.

도움말: 매니페스트 파일에서 애플리케이션 ID를 참조해야 할 경우 모든 매니페스트 속성에서 ${applicationId} 자리표시자를 사용할 수 있습니다. Gradle은 빌드 중에 이 태그를 실제 애플리케이션 ID로 교체합니다. 자세한 내용은 매니페스트에 빌드 변수 삽입을 참고하세요.

버전 차원과 여러 제품 버전 결합

일부 경우에는 여러 제품 버전의 구성을 조합하는 것이 좋습니다. 예를 들어, API 수준을 기준으로 'full' 및 'demo' 제품 버전에 서로 다른 구성을 생성할 수 있습니다. 이 작업을 위해 Gradle용 Android 플러그인을 사용하면 여러 개의 제품 버전 그룹을 버전 차원으로 생성할 수 있습니다. 앱을 빌드할 때 Gradle은 빌드 유형 구성과 함께 최종 빌드 변형을 생성하기 위해 개발자가 정의하는 각 버전 차원에서 제품 버전 구성을 조합합니다. Gradle은 동일한 버전 차원에 속한 제품 버전을 조합하지 않습니다.

다음 코드 샘플에서는 flavorDimensions 속성을 사용하여 'full' 및 'demo' 제품 버전을 그룹화하는 'mode' 버전 차원과 API 수준을 기반으로 제품 버전 구성을 그룹화하는 'api' 버전 차원을 생성합니다.

Groovy

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion 24
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion 23
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion 21
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    getByName("debug") {...}
    getByName("release") {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions += listOf("api", "mode")

  productFlavors {
    create("demo") {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension = "mode"
      ...
    }

    create("full") {
      dimension = "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    create("minApi24") {
      dimension = "api"
      minSdk = 24
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode = 30000 + (android.defaultConfig.versionCode ?: 0)
      versionNameSuffix = "-minApi24"
      ...
    }

    create("minApi23") {
      dimension = "api"
      minSdk = 23
      versionCode = 20000  + (android.defaultConfig.versionCode ?: 0)
      versionNameSuffix = "-minApi23"
      ...
    }

    create("minApi21") {
      dimension = "api"
      minSdk = 21
      versionCode = 10000  + (android.defaultConfig.versionCode ?: 0)
      versionNameSuffix = "-minApi21"
      ...
    }
  }
}
...

Gradle이 생성하는 빌드 변형의 개수는 각 버전 차원에 있는 버전의 수와 개발자가 구성하는 빌드 유형의 수를 곱한 값과 같습니다. Gradle이 각 빌드 변형 또는 빌드 변형에 대응하는 아티팩트의 이름을 지정하면 우선순위가 높은 버전 차원에 속한 제품 버전이 먼저 나타나고 그 다음에 우선순위가 낮은 차원의 제품 버전과 빌드 유형이 차례대로 나타납니다. Gradle은 위에서 예로 든 빌드 구성을 사용하여 다음과 같은 이름 지정 체계로 총 12개의 빌드 변형을 생성합니다.

빌드 변형: [minApi24, minApi23, minApi21][Demo, Full][Debug, Release]
빌드 변형에 대응하는 APK: app-[minApi24, minApi23, minApi21]-[demo, full]-[debug, release].apk
예:
빌드 변형: minApi24DemoDebug
빌드 변형에 대응하는 APK: app-minApi24-demo-debug.apk

개별 제품 버전 및 빌드 변형에 생성할 수 있는 소스 세트 디렉터리 외에, 제품 버전의 각 조합에도 소스 세트 디렉터리를 만들 수 있습니다. 예를 들어, 자바 소스를 생성하여 src/demoMinApi24/java/ 디렉터리에 추가할 수 있고, Gradle은 이러한 두 제품 버전을 조합한 변형을 빌드할 때만 이러한 소스를 사용합니다. 제품 버전 조합을 위해 생성하는 소스 세트는 개별 제품 버전에 속한 소스 세트보다 우선순위가 높습니다. Gradle이 리소스를 병합하는 방식과 소스 세트에 관해 자세히 알아보려면 소스 세트 생성 방법에 관한 섹션을 읽어보세요.

변형 필터링

Gradle은 개발자가 구성하는 제품 버전과 빌드 유형의 가능한 모든 조합을 위한 빌드 변형을 생성합니다. 하지만, 필요하지 않거나 프로젝트의 컨텍스트에 맞지 않는 특정 빌드 변형이 있을 수 있습니다. 모듈 레벨 build.gradle 파일에 변형 필터를 생성하여 특정 빌드 변형 구성을 삭제할 수 있습니다.

이전 섹션에서 예로 든 빌드 구성을 사용할 때 앱의 데모 버전으로 API 수준 23 이상만 지원할 계획이라고 가정해 보겠습니다. variantFilter 블록을 사용하여 'minApi21' 및 'demo' 제품 버전을 조합하는 모든 빌드 변형 구성을 필터링할 수 있습니다.

Groovy

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

Kotlin

android {
  ...
  buildTypes {...}

  flavorDimensions += listOf("api", "mode")
  productFlavors {
    create("demo") {...}
    create("full") {...}
    create("minApi24") {...}
    create("minApi23") {...}
    create("minApi21") {...}
  }
}

androidComponents {
    beforeVariants { variantBuilder ->
        // To check for a certain build type, use variantBuilder.buildType == "<buildType>"
        if (variantBuilder.productFlavors.containsAll(listOf("api" to "minApi21", "mode" to "demo"))) {
            // Gradle ignores any variants that satisfy the conditions above.
            variantBuilder.enabled = false
        }
    }
}
...

빌드 구성에 변형 필터를 추가하고 알림바에서 Sync Now를 클릭하면 Gradle에서 개발자가 지정하는 조건을 충족하는 빌드 변형을 모두 무시하므로, 메뉴 바에서 Build > Select Build Variant를 클릭하거나 도구 창 모음에서 Build Variants 를 클릭하면 이러한 빌드 변형이 더 이상 드롭다운 메뉴에 나타나지 않습니다.

소스 세트 생성

기본적으로 Android 스튜디오는 모든 빌드 변형 간에 공유하려는 모든 항목에 main/ 소스 세트 및 디렉터리를 생성합니다. 그러나 특정 빌드 유형, 제품 버전(그리고 버전 차원을 사용하는 경우 제품 버전의 조합) 및 빌드 변형에 Gradle이 컴파일하고 패키징하는 파일을 정확히 제어하기 위해 새로운 소스 세트를 생성할 수 있습니다. 예를 들어, 기본적인 기능은 main/ 소스 세트에 정의하고, 제품 버전 소스 세트를 사용하여 다양한 클라이언트를 위해 앱 브랜드를 변경하거나 디버그 빌드 유형을 사용하는 빌드 변형에만 특별 권한과 로깅 기능을 포함할 수 있습니다.

Gradle은 개발자가 main/ 소스 세트와 유사한 방식을 사용하여 소스 세트 파일과 디렉터리를 구성할 것으로 예상합니다. 예를 들어, Gradle은 'debug' 빌드 유형 전용의 자바 클래스 파일이 src/debug/java/ 디렉터리에 있을 것으로 예상합니다.

Gradle용 Android 플러그인은 각 빌드 유형, 제품 버전 및 빌드 변형에 관한 파일 구성 방법을 보여주는 유용한 Gradle 작업을 제공합니다. 예를 들어, 다음 작업 출력 샘플은 Gradle이 'debug' 빌드 유형의 특정 파일을 찾을 것으로 예상되는 위치를 설명합니다.

------------------------------------------------------------
Project :app
------------------------------------------------------------

...

debug
----
Compile configuration: compile
build.gradle name: android.sourceSets.debug
Java sources: [app/src/debug/java]
Manifest file: app/src/debug/AndroidManifest.xml
Android resources: [app/src/debug/res]
Assets: [app/src/debug/assets]
AIDL sources: [app/src/debug/aidl]
RenderScript sources: [app/src/debug/rs]
JNI sources: [app/src/debug/jni]
JNI libraries: [app/src/debug/jniLibs]
Java-style resources: [app/src/debug/resources]

이 출력을 보려면 다음과 같이 진행합니다.

  1. IDE 창 오른쪽에서 Gradle 을 클릭합니다.
  2. MyApplication > Tasks > android로 이동하여 sourceSets를 더블클릭합니다. Gradle에서 작업을 실행하면 Run 창이 열리고 출력 내용이 표시됩니다.
  3. 표시된 내용이 위와 같은 텍스트 모드가 아닌 경우 Run 창의 왼쪽에 있는 Toggle view 를 클릭합니다.

참고: 이 작업 출력은 앱 테스트를 실행하는 데 사용할 파일의 소스 세트(예: test/androidTest/ 테스트 소스 세트)를 구성하는 방법도 보여줍니다.

새 빌드 변형을 생성할 때 Android 스튜디오에서 소스 세트 디렉터리를 자동으로 생성하지는 않지만, 개발자에게 도움이 되는 몇 가지 옵션을 제공합니다. 예를 들어, 'debug' 빌드 유형에 java/ 디렉터리만 만들려면 다음과 같이 하면 됩니다.

  1. Project 창을 열고 창 상단의 드롭다운 메뉴에서 Project 보기를 선택합니다.
  2. MyProject/app/src/로 이동합니다.
  3. src 디렉터리를 마우스 오른쪽 버튼으로 클릭하고 New > Folder > Java Folder를 선택합니다.
  4. Target Source Set 옆의 드롭다운 메뉴에서 debug를 선택합니다.
  5. Finish를 클릭합니다.

Android 스튜디오에서는 디버그 빌드 유형에 소스 세트 디렉터리를 생성한 다음, 그 안에 java/ 디렉터리를 생성합니다. 또는, 특정 빌드 변형을 위해 프로젝트에 새 파일을 추가할 때 Android 스튜디오가 자동으로 디렉터리를 생성하도록 설정할 수 있습니다. 예를 들어, 'debug' 빌드 유형에 Values XML 파일을 생성하려면 다음과 같이 하세요.

  1. 동일한 Project 창에서 src 디렉터리를 마우스 오른쪽 버튼으로 클릭하고 New > XML > Values XML File을 선택합니다.
  2. XML 파일의 이름을 입력하거나 기본 이름을 유지합니다.
  3. Target Source Set 옆의 드롭다운 메뉴에서 debug를 선택합니다.
  4. Finish를 클릭합니다.

'debug' 빌드 유형이 타겟 소스 세트로 지정되었으므로 Android 스튜디오는 XML 파일을 생성할 때 필요한 디렉터리를 자동으로 생성합니다. 디렉터리 구조의 결과는 그림 2와 같아야 합니다.

그림 2. 디버그 빌드 유형의 새로운 소스 세트 디렉터리

또한, 동일한 절차를 사용하여 제품 버전(예: src/demo/)과 빌드 변형(예: src/demoDebug/)의 소스 세트 디렉터리를 생성할 수도 있습니다. 그 밖에도 특정 빌드 변형을 타겟팅하는 테스트 소스 세트를 생성할 수 있습니다(예: src/androidTestDemoDebug/). 자세한 내용은 테스트 소스 세트를 참고하세요.

기본 소스 세트 구성 변경

Gradle이 예상하는 기본 소스 세트 파일 구조로 구성되지 않은 소스가 있는 경우에는 앞서 소스 세트 생성 섹션에서 설명한 것처럼 sourceSets 블록을 사용하여 Gradle이 소스 세트의 구성요소별로 파일을 수집하는 위치를 변경할 수 있습니다. 파일의 위치를 변경할 필요는 없습니다. 개발자는 Gradle이 각 소스 세트 구성요소의 파일을 찾을 것으로 예상되는 모듈 레벨 build.gradle 파일의 상대적인 경로를 Gradle에 제공하기만 하면 됩니다. 어떤 구성요소를 구성할 수 있는지, 이러한 구성요소를 여러 파일이나 디렉터리로 매핑할 수 있는지 알아보려면 Android Gradle 플러그인 API 참조를 확인하세요.

다음은 app/other/ 디렉터리의 소스를 main 소스 세트의 특정 구성요소로 매핑하고 androidTest 소스 세트의 루트 디렉터리를 변경하는 코드 샘플입니다.

Groovy

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // If you list multiple directories, Gradle uses all of them to collect
      // sources. Because Gradle gives these directories equal priority, if
      // you define the same resource in more than one directory, you get an
      // error when merging resources. The default directory is 'src/main/res'.
      res.srcDirs = ['other/res1', 'other/res2']

      // Note: You should avoid specifying a directory which is a parent to one
      // or more other directories you specify. For example, avoid the following:
      // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
      // You should specify either only the root 'other/res1' directory, or only the
      // nested 'other/res1/layouts' and 'other/res1/strings' directories.

      // For each source set, you can specify only one Android manifest.
      // By default, Android Studio creates a manifest for your main source
      // set in the src/main/ directory.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying the
      // configuration below for the androidTest source set, Gradle looks for Java
      // sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

Kotlin

android {
  ...
  // Encapsulates configurations for the main source set.
  sourceSets.getByName("main") {
    // Changes the directory for Java sources. The default directory is
    // 'src/main/java'.
    java.setSrcDirs("other/java")

    // If you list multiple directories, Gradle uses all of them to collect
    // sources. Because Gradle gives these directories equal priority, if
    // you define the same resource in more than one directory, you get an
    // error when merging resources. The default directory is 'src/main/res'.
    res.setSrcDirs("other/res1", "other/res2")

    // Note: You should avoid specifying a directory which is a parent to one
    // or more other directories you specify. For example, avoid the following:
    // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
    // You should specify either only the root 'other/res1' directory, or only the
    // nested 'other/res1/layouts' and 'other/res1/strings' directories.

    // For each source set, you can specify only one Android manifest.
    // By default, Android Studio creates a manifest for your main source
    // set in the src/main/ directory.
    manifest.srcFile("other/AndroidManifest.xml")
    ...
  }

  // Create additional blocks to configure other source sets.
  sourceSets.getByName("androidTest") {
    // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying the
      // configuration below for the androidTest source set, Gradle looks for Java
      // sources only in the src/tests/java/ directory.
      setRoot("src/tests")
      ...
  }
}
...

소스 세트로 빌드

소스 세트 디렉터리를 사용하여 특정 구성으로만 패키징하려는 코드와 리소스를 포함할 수 있습니다. 예를 들어, 'demo' 제품 버전과 'debug' 빌드 유형의 교차 제품(crossproduct)인 'demoDebug' 빌드 변형을 빌드하는 경우, Gradle은 아래의 디렉터리를 찾아서 다음과 같이 우선순위를 부여합니다.

  1. src/demoDebug/ (빌드 변형 소스 세트)
  2. src/debug/ (빌드 유형 소스 세트)
  3. src/demo/ (제품 버전 소스 세트)
  4. src/main/ (기본 소스 세트)

참고: 여러 제품 버전을 조합할 경우 제품 버전 간의 우선순위는 제품 버전이 속한 버전 차원에 따라 결정됩니다. android.flavorDimensions 속성이 있는 버전 차원을 나열할 때 목록의 첫 번째 버전 차원에 속한 제품 버전이 두 번째 버전 차원에 속한 제품 버전보다 우선순위가 높고 그 이후로도 마찬가지입니다. 또한, 제품 버전의 조합을 위해 생성하는 소스 세트는 각각의 개별 제품 버전에 속한 소스 세트보다 우선순위가 높습니다.

위에 나열된 순서는 Gradle이 코드와 리소스를 조합할 때 어떤 소스 세트의 우선순위가 더 높은지 판별합니다. demoDebug/ 소스 세트 디렉터리에는 빌드 변형에 관련된 파일이 포함될 가능성이 높으므로 debug/에도 정의된 파일이 demoDebug/에 포함된 경우 Gradle은 demoDebug/ 소스 세트에 있는 파일을 사용합니다. 마찬가지로, Gradle은 main/에 있는 파일보다 빌드 유형 및 제품 버전 소스 세트에 있는 동일한 파일에 더 높은 우선순위를 부여합니다. Gradle은 다음과 같은 빌드 규칙을 적용할 때 이 우선순위를 고려합니다.

  • java/ 디렉터리에 있는 모든 소스 코드가 함께 컴파일되어 단일 출력을 생성합니다.

    참고: 빌드 변형에 속한 두 개 이상의 소스 세트 디렉터리에 동일한 자바 클래스가 정의되어 있다면 Gradle에서 빌드 변형의 빌드 오류가 발생합니다. 예를 들어 디버그 앱을 빌드할 때는 src/debug/Utility.javasrc/main/Utility.java 둘 다 정의할 수 없습니다. 그 이유는 Gradle이 빌드 프로세스 중에 두 디렉터리를 확인하고 '중복 클래스' 오류를 발생시키기 때문입니다. 다른 빌드 유형에 다른 버전의 Utility.java를 원하는 경우에는 각 빌드 유형이 자체 파일 버전을 정의하고 이를 main/ 소스 세트에 포함하지 않도록 할 수 있습니다.

  • 여러 매니페스트가 단일 매니페스트로 함께 병합됩니다. 위의 목록과 동일한 순서로 우선순위가 부여됩니다. 즉, 빌드 유형의 매니페스트 설정은 제품 버전의 매니페스트 설정보다 우선합니다. 자세히 알아보려면 매니페스트 병합을 참조하세요.
  • 마찬가지로, values/ 디렉터리의 파일도 함께 병합됩니다. 두 파일이 동일한 이름을 공유하는 경우(예: 두 개의 strings.xml 파일) 우선순위는 위의 목록과 같은 순서로 지정됩니다. 즉, 빌드 유형 소스 집합의 파일에 정의된 값은 제품 버전의 동일한 파일에 정의된 값보다 우선합니다.
  • res/asset/ 디렉터리에 있는 리소스는 함께 패키징됩니다. 동일한 이름의 리소스가 둘 이상의 소스 세트에 정의된 경우 우선순위는 위의 목록과 같은 순서로 지정됩니다.
  • 마지막으로 앱을 빌드할 때 Gradle은 라이브러리 모듈 종속 항목에 포함된 리소스와 매니페스트에는 가장 낮은 우선순위를 부여합니다.

종속 항목 선언

다음 예에서 보는 것처럼, 빌드 변형 또는 테스트 소스 세트의 이름을 Implementation 키워드 앞에 붙여서 특정 빌드 변형 또는 테스트 소스 세트의 종속 항목을 구성할 수 있습니다.

Groovy

dependencies {
    // Adds the local "mylibrary" module as a dependency to the "free" flavor.
    freeImplementation project(":mylibrary")

    // Adds a remote binary dependency only for local tests.
    testImplementation 'junit:junit:4.12'

    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
}

Kotlin

dependencies {
    // Adds the local "mylibrary" module as a dependency to the "free" flavor.
    freeImplementation(project(":mylibrary"))

    // Adds a remote binary dependency only for local tests.
    testImplementation("junit:junit:4.12")

    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation("com.android.support.test.espresso:espresso-core:3.0.2")
}

자세한 내용은 빌드 종속 항목 추가를 참고하세요.

변형 인식 종속성 관리 사용

Android 플러그인 3.0.0 이상에는 라이브러리를 사용할 때 자동으로 변형을 매칭하는 새로운 종속 항목 메커니즘이 포함됩니다. 즉 앱의 debug 변형에서 라이브러리의 debug 변형 등을 자동으로 사용합니다. 이 기능은 버전을 사용할 때도 작동하며 앱의 freeDebug 변형에서 라이브러리의 freeDebug 변형을 사용합니다.

플러그인이 정확하게 변형을 매칭하려면 직접 매칭이 불가능한 경우 매칭 폴백을 제공해야 합니다. 앱에서 'staging'이라는 빌드 유형을 구성하지만 라이브러리 종속 항목 중 하나에서는 구성하지 않는 경우를 고려하세요. 앱의 'staging' 버전을 빌드하려고 시도할 때 플러그인에서는 사용할 라이브러리 버전을 알 수 없고 다음과 유사한 오류 메시지가 표시됩니다.

Error:Failed to resolve: Could not resolve project :mylibrary.
Required by:
    project :app

변형 매칭과 관련된 빌드 오류 해결

플러그인에는 DSL 요소가 포함되어 있어 Gradle이 앱과 종속 항목 간의 직접적인 변형 매칭이 불가능한 상황을 해결하는 방법을 제어할 수 있습니다. 변형 인식 종속 항목 매칭과 관련된 특정 빌드 오류를 해결하기 위해 사용해야 하는 DSL 속성을 확인하려면 아래 표를 참고하세요.

빌드 오류의 원인 해결 방법

라이브러리 종속 항목에는 없는 빌드 유형이 앱에 포함되어 있습니다.

예를 들어 앱에 'staging' 빌드 유형이 포함되어 있지만 종속항목에는 'debug'와 'release' 빌드 유형만 포함되어 있습니다.

앱에 없는 빌드 유형이 라이브러리 종속 항목에 포함되어 있는 경우에는 문제가 없습니다. 그 이유는 플러그인에서 종속 항목에 앱에 없는 빌드 유형을 요청하지 않기 때문입니다.

다음과 같이 matchingFallbacks를 사용하여 주어진 빌드 유형에 맞는 대체 매칭을 지정합니다.

Groovy


// In the app's build.gradle file.
android {
    buildTypes {
        debug {}
        release {}
        staging {
            // Specifies a sorted list of fallback build types that the
            // plugin should try to use when a dependency does not include a
            // "staging" build type. You may specify as many fallbacks as you
            // like, and the plugin selects the first build type that's
            // available in the dependency.
            matchingFallbacks = ['debug', 'qa', 'release']
        }
    }
}

Kotlin


// In the app's build.gradle file.
android {
    buildTypes {
        getByName("debug") {}
        getByName("release") {}
        create("staging") {
            // Specifies a sorted list of fallback build types that the
            // plugin should try to use when a dependency does not include a
            // "staging" build type. You may specify as many fallbacks as you
            // like, and the plugin selects the first build type that's
            // available in the dependency.
            matchingFallbacks += listOf("debug", "qa", "release")
        }
    }
}

앱과 앱의 라이브러리 종속 항목에 모두 존재하는 버전 차원의 경우 라이브러리에 없는 버전이 앱에 포함됩니다.

예를 들어 앱과 앱의 라이브러리 종속 항목 모두에 'tier' 버전 차원이 포함되어 있습니다. 그러나 앱의 'tier' 차원에는 'free'와 'paid' 버전이 포함되어 있지만 종속 항목에는 동일한 차원의 'demo'와 'paid' 버전만 포함되어 있습니다.

앱과 앱의 라이브러리 종속 항목에 모두 존재하는 버전 차원의 경우 앱에 없는 제품 버전이 라이브러리 종속 항목에 포함되어도 문제가 없습니다. 그 이유는 플러그인에서 종속 항목에 앱에 없는 버전을 요청하지 않기 때문입니다.

다음과 같이 matchingFallbacks를 사용하여 앱의 'free' 제품 버전에 맞는 대체 매칭을 지정합니다.

Groovy


// In the app's build.gradle file.
android {
    defaultConfig{
    // Do not configure matchingFallbacks in the defaultConfig block.
    // Instead, you must specify fallbacks for a given product flavor in the
    // productFlavors block, as shown below.
  }
    flavorDimensions 'tier'
    productFlavors {
        paid {
            dimension 'tier'
            // Because the dependency already includes a "paid" flavor in its
            // "tier" dimension, you don't need to provide a list of fallbacks
            // for the "paid" flavor.
        }
        free {
            dimension 'tier'
            // Specifies a sorted list of fallback flavors that the plugin
            // should try to use when a dependency's matching dimension does
            // not include a "free" flavor. You may specify as many
            // fallbacks as you like, and the plugin selects the first flavor
            // that's available in the dependency's "tier" dimension.
            matchingFallbacks = ['demo', 'trial']
        }
    }
}

Kotlin


// In the app's build.gradle file.
android {
    defaultConfig{
    // Do not configure matchingFallbacks in the defaultConfig block.
    // Instead, you must specify fallbacks for a given product flavor in the
    // productFlavors block, as shown below.
  }
    flavorDimensions += "tier"
    productFlavors {
        create("paid") {
            dimension = "tier"
            // Because the dependency already includes a "paid" flavor in its
            // "tier" dimension, you don't need to provide a list of fallbacks
            // for the "paid" flavor.
        }
        create("free") {
            dimension = "tier"
            // Specifies a sorted list of fallback flavors that the plugin
            // should try to use when a dependency's matching dimension does
            // not include a "free" flavor. You may specify as many
            // fallbacks as you like, and the plugin selects the first flavor
            // that's available in the dependency's "tier" dimension.
            matchingFallbacks += listOf("demo", "trial")
        }
    }
}

라이브러리 종속 항목에 앱에 없는 버전 차원이 포함되어 있습니다.

예를 들어 라이브러리 종속 항목에 'minApi' 차원의 버전이 포함되어 있지만 앱에는 'tier' 차원의 버전만 포함되어 있습니다. 따라서 앱의 'freeDebug' 버전을 빌드할 때 플러그인에서 'minApi23Debug' 또는 'minApi18Debug' 중 어느 종속 항목 버전을 사용할지 알 수 없습니다.

라이브러리 종속 항목에 없는 버전 차원이 앱에 포함되어 있는 경우에는 문제가 없습니다. 그 이유는 플러그인에서 종속 항목에 있는 차원의 버전만 매칭하기 때문입니다. 예를 들어 종속 항목에 ABI의 차원이 포함되지 않은 경우 앱의 'freeX86Debug' 버전에서는 단순히 종속 항목의 'freeDebug' 버전을 사용합니다.

아래 샘플과 같이 defaultConfig 블록의 missingDimensionStrategy를 사용하여 플러그인이 누락된 각 차원에서 선택해야 하는 기본 버전을 지정합니다. productFlavors 블록에서 선택한 내용을 재정의할 수도 있으므로 각 버전에서 누락된 차원의 다른 매칭 전략을 지정할 수 있습니다.

Groovy


// In the app's build.gradle file.
android {
    defaultConfig{
    // Specifies a sorted list of flavors that the plugin should try to use from
    // a given dimension. The following tells the plugin that, when encountering
    // a dependency that includes a "minApi" dimension, it should select the
    // "minApi18" flavor. You can include additional flavor names to provide a
    // sorted list of fallbacks for the dimension.
    missingDimensionStrategy 'minApi', 'minApi18', 'minApi23'
    // You should specify a missingDimensionStrategy property for each
    // dimension that exists in a local dependency but not in your app.
    missingDimensionStrategy 'abi', 'x86', 'arm64'
    }
    flavorDimensions 'tier'
    productFlavors {
        free {
            dimension 'tier'
            // You can override the default selection at the product flavor
            // level by configuring another missingDimensionStrategy property
            // for the 'minApi' dimension.
            missingDimensionStrategy 'minApi', 'minApi23', 'minApi18'
        }
        paid {}
    }
}

Kotlin


// In the app's build.gradle file.
android {
    defaultConfig{
    // Specifies a sorted list of flavors that the plugin should try to use from
    // a given dimension. The following tells the plugin that, when encountering
    // a dependency that includes a "minApi" dimension, it should select the
    // "minApi18" flavor. You can include additional flavor names to provide a
    // sorted list of fallbacks for the dimension.
    missingDimensionStrategy("minApi", "minApi18", "minApi23")
    // You should specify a missingDimensionStrategy property for each
    // dimension that exists in a local dependency but not in your app.
    missingDimensionStrategy("abi", "x86", "arm64")
    }
    flavorDimensions "tier"
    productFlavors {
        create("free") {
            dimension = "tier"
            // You can override the default selection at the product flavor
            // level by configuring another missingDimensionStrategy property
            // for the "minApi" dimension.
            missingDimensionStrategy("minApi", "minApi23", "minApi18")
        }
        create("paid") {}
    }
}

자세한 내용은 Android 플러그인 DSL 참조의 matchingFallbacksmissingDimensionStrategy를 참고하세요.

서명 설정 구성

출시 빌드의 서명 구성을 명시적으로 정의하지 않는 한 Gradle은 이 빌드의 APK나 AAB에 서명하지 않습니다. 서명 키가 아직 없다면 Android 스튜디오를 사용하여 업로드 키 및 키 저장소를 생성하는 방법을 참고하세요.

Gradle 빌드 구성을 사용하여 출시 빌드 유형의 서명 구성을 수동으로 구성하려면 다음을 따르세요.

  1. 키 저장소를 생성합니다. 키 저장소는 비공개 키 세트가 포함된 바이너리 파일입니다. 키 저장소는 안전하고 보안이 유지되는 장소에 보관해야 합니다.
  2. 비공개 키를 생성합니다. 비공개 키는 배포를 위해 앱에 서명하는 데 사용되고 앱에 포함되거나 승인되지 않은 제3자에게 공개되지 않습니다.
  3. 서명 구성을 모듈 수준 build.gradle 파일에 추가합니다.

    Groovy

    ...
    android {
        ...
        defaultConfig {...}
        signingConfigs {
            release {
                storeFile file("myreleasekey.keystore")
                storePassword "password"
                keyAlias "MyReleaseKey"
                keyPassword "password"
            }
        }
        buildTypes {
            release {
                ...
                signingConfig signingConfigs.release
            }
        }
    }

    Kotlin

    ...
    android {
        ...
        defaultConfig {...}
        signingConfigs {
            create("release") {
                storeFile = file("myreleasekey.keystore")
                storePassword = "password"
                keyAlias = "MyReleaseKey"
                keyPassword = "password"
            }
        }
        buildTypes {
            getByName("release") {
                ...
                signingConfig = signingConfigs.getByName("release")
            }
        }
    }

참고: 출시 키와 키 저장소의 비밀번호를 빌드 파일에 포함하는 것은 보안에 좋지 않습니다. 대신 환경 변수에서 이러한 비밀번호를 가져오도록 빌드 파일을 구성하거나 빌드 프로세스에서 이러한 비밀번호를 입력하도록 메시지를 표시할 수 있습니다.

환경 변수에서 이러한 비밀번호를 가져오려면 다음과 같이 하세요.

Groovy

storePassword System.getenv("KSTOREPWD")
keyPassword System.getenv("KEYPWD")

Kotlin

storePassword = System.getenv("KSTOREPWD")
keyPassword = System.getenv("KEYPWD")

명령줄에서 빌드를 호출하는 경우, 빌드 프로세스에서 비밀번호 입력을 요청하는 메시지를 표시하도록 하려면 다음과 같이 하세요.

Groovy

storePassword System.console().readLine("\nKeystore password: ")
keyPassword System.console().readLine("\nKey password: ")

Kotlin

storePassword = System.console().readLine("\nKeystore password: ")
keyPassword = System.console().readLine("\nKey password: ")

이 프로세스를 완료한 후 앱을 배포하고 Google Play에 게시할 수 있습니다.

경고: 키 저장소와 비공개 키는 안전하고 보안이 유지되는 장소에 보관해야 하며, 안전하게 백업되어야 합니다. Play 앱 서명을 사용하다가 업로드 키를 분실하면 Play Console을 사용하여 재설정을 요청할 수 있습니다. Play 앱 서명 없이 앱(2021년 8월 이전에 생성된 앱)을 게시하는 경우 앱 서명 키를 분실하면 앱 업데이트를 게시할 수 없습니다. 항상 같은 키로 모든 버전의 앱에 서명해야 하기 때문입니다.

Wear OS 앱 서명

Wear OS 앱을 게시할 때 시계 APK와 선택적 전화 APK에 모두 서명해야 합니다. Wear OS 앱을 패키징하고 서명하는 방법에 관한 자세한 내용은 Wear 앱 패키지 및 배포를 참고하세요.