หน้านี้ได้รับการแปลโดย Cloud Translation API

เคล็ดลับและสูตร Gradle

Gradle และปลั๊กอิน Android สำหรับ Gradle มอบวิธี คอมไพล์ที่ยืดหยุ่น และสร้างแพ็กเกจแอป Android หรือไลบรารีของคุณ หน้านี้รวบรวมเนื้อหาบางส่วน เคล็ดลับและการกำหนดค่าที่เป็นประโยชน์เพื่อช่วยให้คุณได้รับประโยชน์สูงสุดจากบิลด์แต่ละรายการ หากคุณต้องการเรียนรู้วิธีทำให้งานสร้างของคุณเร็วขึ้น โปรดอ่าน เพิ่มประสิทธิภาพความเร็วในการสร้าง

หากคุณเพิ่งเริ่มใช้ Gradle เรียนรู้พื้นฐานการใช้งานโดยอ่านกำหนดค่าบิลด์ของคุณ คุณยังตรวจสอบ ข้อมูลอ้างอิง DSL ของปลั๊กอิน Android เพื่อดูข้อมูลเพิ่มเติมเกี่ยวกับพร็อพเพอร์ตี้ที่ใช้ในหน้านี้

จัดการโปรเจ็กต์และแหล่งที่มา

ต่อไปนี้เป็นการกำหนดค่าบางส่วนเพื่อจัดการโมดูลของโครงการและโมดูล แหล่งที่มา หากต้องการเรียนรู้เพิ่มเติมเกี่ยวกับการสร้างและการจัดการโปรเจ็กต์และโมดูล โปรดอ่าน ภาพรวมโครงการ

เปลี่ยนการกำหนดค่าชุดแหล่งที่มาเริ่มต้น

คุณสามารถใช้การบล็อก sourceSets ได้ใน build.gradle ระดับโมดูล เพื่อเปลี่ยนตำแหน่งที่ Gradle รวบรวมไฟล์สำหรับแต่ละองค์ประกอบของ ชุดแหล่งที่มา

ดึงดูด

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.srcDirs = ['other/res1', 'other/res2']

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

Kotlin

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    getByName("main") {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.setSrcDirs("other/java")

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.setSrcDirs("other/res1", "other/res2")

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile("other/AndroidManifest.xml")
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot("src/tests")
      ...
    }
  }
}
...

จัดการไลบรารีและทรัพยากร Dependency

Gradle มีกลไกที่มีประสิทธิภาพในการจัดการทรัพยากร Dependency ไม่ว่าจะเป็น ห้องสมุดระยะไกลหรือโมดูลห้องสมุดในท้องถิ่น

กำหนดเป้าหมายบิลด์ที่เฉพาะเจาะจงด้วยการกำหนดค่าทรัพยากร Dependency

หากคุณต้องการทรัพยากร Dependency สำหรับชุดต้นทางเวอร์ชันบิลด์ที่เฉพาะเจาะจงหรือชุดแหล่งที่มาของการทดสอบ ให้ใช้อักษรตัวพิมพ์ใหญ่ การอ้างอิง การกำหนดค่า และใส่คำนำหน้าด้วยชื่อตัวแปรของบิลด์หรือ ชุดแหล่งที่มาของการทดสอบ

ดึงดูด

android {...}

// Creates Gradle dependency configurations to use in the dependencies block.
configurations {
  // For variants that combine a product flavor and build type, you need to
  // intitialize a placeholder for its dependency configuration.
  freeDebugRuntimeOnly{}
  ...
}

dependencies {
    // Adds an implementation dependency only to the "free" product flavor.
    freeImplementation 'com.google.firebase:firebase-ads:21.5.1'
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    freeDebugRuntimeOnly fileTree(dir: 'libs', include: ['*.jar'])
    // Adds a remote binary dependency only for local tests.
    testImplementation 'junit:junit:4.12'
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.5.1'
}

Kotlin

android {...}

dependencies {
    // Use ""() notation for custom flavors and build types
    // Adds an implementation dependency only to the "free" product flavor.
    "freeImplementation"("com.google.firebase:firebase-ads:21.5.1")
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    "freeDebugRuntimeOnly"(fileTree("dir" to "libs", "include" to "*.jar"))
    // Adds a remote binary dependency only for local tests.
    testImplementation("junit:junit:4.12")
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation("com.android.support.test.espresso:espresso-core:3.5.1")
}

สร้างแอปเวอร์ชันต่างๆ

Gradle และปลั๊กอิน Android ช่วยให้คุณสร้างเวอร์ชัน แอปจากโมดูลเดียวโดยกำหนดค่าตัวแปรของบิลด์

กำหนดค่ารหัสเวอร์ชันแบบไดนามิก

โดยค่าเริ่มต้น เมื่อ Gradle สร้าง APK สำหรับโปรเจ็กต์ของคุณ APK แต่ละรายการจะมี ข้อมูลเวอร์ชันเดียวกันตามที่ระบุไว้ในไฟล์ build.gradle ระดับโมดูล เนื่องจาก Google Play Store ไม่อนุญาตให้ใช้ APK หลายรายการสำหรับแอปเดียวกัน ที่มีข้อมูลเวอร์ชันเหมือนกันทั้งหมด คุณต้องตรวจสอบว่า APK แต่ละรายการ versionCode เฉพาะของตนเองก่อนคุณ อัปโหลดไปยัง Play Store

ซึ่งทำได้โดยใช้ตรรกะบิลด์ที่กำหนดเองซึ่งจะกําหนดรหัสเวอร์ชันอื่น ไปยัง APK แต่ละรายการ ณ เวลาบิลด์ เช่น เมื่อสร้าง APK แยกกันสำหรับแต่ละ APK ABI การกำหนดเวอร์ชัน APK อัตโนมัติของ APK จะมีลักษณะดังนี้

ดึงดูด

android {
  ...
  defaultConfig {
    ...
    versionCode 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
ext.abiCodes = ['armeabi-v7a':1, mips:2, x86:3]

// For per-density APKs, create a similar map like this:
// ext.densityCodes = ['hdpi': 1, 'xhdpi': 2, 'xxhdpi': 3, 'xxxhdpi': 4]

import com.android.build.OutputFile

// For each APK output variant, override versionCode with a combination of
// ext.abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
android.applicationVariants.all { variant ->

  // Assigns a different version code for each output APK
  // other than the universal APK.
  variant.outputs.each { output ->

    // Stores the value of ext.abiCodes that is associated with the ABI for this variant.
    def baseAbiVersionCode =
            // Determines the ABI for this variant and returns the mapped value.
            project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))

    // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
    // the following code does not override the version code for universal APKs.
    // However, because we want universal APKs to have the lowest version code,
    // this outcome is desirable.
    if (baseAbiVersionCode != null) {

      // Assigns the new version code to versionCodeOverride, which changes the version code
      // for only the output APK, not for the variant itself. Skipping this step simply
      // causes Gradle to use the value of variant.versionCode for the APK.
      output.versionCodeOverride =
              baseAbiVersionCode * 1000 + variant.versionCode
    }
  }
}

Kotlin

android {
  ...
  defaultConfig {
    ...
    versionCode = 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
val abiCodes = mapOf("armeabi-v7a" to 1, "mips" to 2, "x86" to 3)

// For per-density APKs, create a similar map like this:
// val densityCodes = mapOf("hdpi" to 1, "xhdpi" to 2, "xxhdpi" to 3, "xxxhdpi" to 4)

import com.android.build.api.variant.FilterConfiguration.FilterType.*

// For each APK output variant, override versionCode with a combination of
// abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
androidComponents {
    onVariants { variant ->

        // Assigns a different version code for each output APK
        // other than the universal APK.
        variant.outputs.forEach { output ->
            val name = output.filters.find { it.filterType == ABI }?.identifier

            // Stores the value of abiCodes that is associated with the ABI for this variant.
            val baseAbiCode = abiCodes[name]
            // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
            // the following code does not override the version code for universal APKs.
            // However, because we want universal APKs to have the lowest version code,
            // this outcome is desirable.
            if (baseAbiCode != null) {
                // Assigns the new version code to output.versionCode, which changes the version code
                // for only the output APK, not for the variant itself.
                output.versionCode.set(baseAbiCode * 1000 + (output.versionCode.get() ?: 0))
            }
        }
    }
}

รวมหลากหลายรสชาติของผลิตภัณฑ์

ในบางกรณี คุณอาจต้องรวมการกำหนดค่า จากผลิตภัณฑ์หลากหลายรสชาติ โดยปลั๊กอิน Android สำหรับ Gradle ช่วยให้คุณสามารถสร้างกลุ่มของรสชาติผลิตภัณฑ์ที่เรียกว่า รสชาติ ขนาด 300 องศา

ตัวอย่างโค้ดต่อไปนี้ใช้เมธอด flavorDimensions เพื่อสร้าง "โหมด" มิติข้อมูลเวอร์ชันให้กับกลุ่ม "เต็ม" และ "สาธิต" รสชาติของผลิตภัณฑ์ และ "API" มิติข้อมูลเวอร์ชันให้กับกลุ่ม การกำหนดค่าเวอร์ชันผลิตภัณฑ์ตามระดับ API จากนั้น Gradle รวม รสชาติของผลิตภัณฑ์จาก "mode" โดยใช้มิติข้อมูลของ "api"

ดึงดูด

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion '24'
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion '23'
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion '21'
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    getByName("debug") {...}
    getByName("release") {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions += listOf("api", "mode")

  productFlavors {
    create("demo") {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension = "mode"
      ...
    }

    create("full") {
      dimension = "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    create("minApi24") {
      dimension = "api"
      minSdkVersion(24)
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode = 30000 + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi24"
      ...
    }

    create("minApi23") {
      dimension = "api"
      minSdkVersion(23)
      versionCode = 20000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi23"
      ...
    }

    create("minApi21") {
      dimension = "api"
      minSdkVersion(21)
      versionCode = 10000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi21"
      ...
    }
  }
}
...

กรองตัวแปร

คุณสามารถกรอง ตัวแปรของบิลด์ที่คุณไม่ต้องการให้ใช้ บล็อก variantFilter ในไฟล์ build.gradle ของโมดูล โค้ดตัวอย่างต่อไปนี้จะบอก Gradle ไม่ให้สร้างตัวแปรใดๆ ที่รวม "minApi21" และ "สาธิต" รสชาติของผลิตภัณฑ์:

ดึงดูด

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

Kotlin

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    create("demo") {...}
    create("full") {...}
    create("minApi24") {...}
    create("minApi23") {...}
    create("minApi21") {...}
  }
}

androidComponents {
    beforeVariants { variantBuilder ->
        // To check for a certain build type, use variantBuilder.buildType == "<buildType>"
        if (variantBuilder.productFlavors.containsAll(listOf("api" to "minApi21", "mode" to "demo"))) {
            // Gradle ignores any variants that satisfy the conditions above.
            variantBuilder.enabled = false
        }
    }
}
...

ทดสอบแอป

หากต้องการดูข้อมูลเพิ่มเติมเกี่ยวกับการเรียกใช้การทดสอบหน่วยในเครื่องและแบบรวม โปรดอ่านทดสอบแอป

กำหนดค่าตัวเลือก Lint

คุณสามารถกำหนดค่าตัวเลือก Lint บางอย่างโดยใช้ lintOptions ในไฟล์ build.gradle ระดับโมดูล ถึง ดูข้อมูลเพิ่มเติมเกี่ยวกับการใช้ Lint สำหรับโปรเจ็กต์ Android ได้ที่ปรับปรุงโค้ดของคุณด้วย Lint

ดึงดูด

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable 'TypographyFractions','TypographyQuotes'
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable 'RtlHardcoded','RtlCompat', 'RtlEnabled'
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly 'NewApi', 'InlinedApi'
        // If set to true, turns off analysis progress reporting by lint.
        quiet true
        // if set to true (default), stops the build if errors are found.
        abortOnError false
        // if true, only report errors.
        ignoreWarnings true
    }
}
...

Kotlin

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable("TypographyFractions")
        disable("TypographyQuotes")
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable("RtlHardcoded")
        enable("RtlCompat")
        enable("RtlEnabled")
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly("NewApi", "InlinedApi")
        // If set to true, turns off analysis progress reporting by lint.
        quiet = true
        // if set to true (default), stops the build if errors are found.
        abortOnError = false
        // if true, only report errors.
        ignoreWarnings = true
    }
}
...

กำหนดการตั้งค่าไฟล์ Manifest สำหรับการใช้เครื่องมือ

เมื่อ Gradle สร้าง APK ทดสอบของคุณ ก็จะสร้างไฟล์ AndroidManifest.xml ขึ้นโดยอัตโนมัติและ กำหนดค่าด้วย <instrumentation> คุณสามารถเปลี่ยนการตั้งค่าบางอย่างสำหรับโหนดนี้โดยการสร้าง ไฟล์ Manifest อื่นในชุดแหล่งที่มาของการทดสอบ หรือ กำลังกำหนดค่าไฟล์ build.gradle ระดับโมดูลของคุณ ดังที่แสดงใน ตัวอย่างโค้ดต่อไปนี้

ดึงดูด

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest true
  }
}
...

Kotlin

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId = "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner = "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling = true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest = true
  }
}
...

เปลี่ยนประเภทบิลด์ทดสอบ

โดยค่าเริ่มต้น การทดสอบทั้งหมดจะทำงานกับบิลด์การแก้ไขข้อบกพร่อง คุณสามารถเปลี่ยนแปลง ไปยังประเภทบิลด์อื่นโดยใช้พร็อพเพอร์ตี้ testBuildType ใน ไฟล์ build.gradle ระดับโมดูลของคุณ ตัวอย่างเช่น หากคุณต้องการ ทำการทดสอบกับ "การทดลองใช้" ประเภทบิลด์ แก้ไขไฟล์ตามที่แสดงใน ข้อมูลโค้ดต่อไปนี้

ดึงดูด

android {
    ...
    testBuildType "staging"
}

Kotlin

android {
    ...
    testBuildType "staging"
}

กำหนดค่าตัวเลือกการทดสอบ Gradle

ในการระบุตัวเลือกที่เปลี่ยนวิธีที่ Gradle เรียกใช้การทดสอบทั้งหมดของคุณ ให้กำหนดค่า testOptions ในระดับโมดูล build.gradle

ดึงดูด

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

Kotlin

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

หากต้องการระบุตัวเลือกเฉพาะสำหรับการทดสอบหน่วยในเครื่อง ให้กำหนดค่า บล็อก testOptions.unitTests

ดึงดูด

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

Kotlin

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

เพิ่มประสิทธิภาพการสร้างของคุณ

ส่วนนี้จะอธิบายการกำหนดค่าบางอย่างเพื่อช่วยเพิ่มความเร็ว งานสร้างที่เพิ่มขึ้นเรื่อยๆ หากต้องการดูข้อมูลเพิ่มเติม โปรดอ่าน เพิ่มประสิทธิภาพความเร็วในการสร้าง

ย่อโค้ดของคุณ

Android Studio ใช้ R8 ซึ่งใช้ไฟล์กฎ ProGuard ในการย่อโค้ด สำหรับมือใหม่ Android Studio จะใช้ไฟล์การตั้งค่าเริ่มต้น (proguard-android.txt) จาก tools/proguard/folder ของ Android SDK หากต้องการลดขนาดโค้ดให้เล็กลง ให้ลองใช้ proguard-android-optimize.txt ไฟล์ที่อยู่ในตำแหน่งเดียวกัน

ดึงดูด

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

Kotlin

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

หากต้องการเพิ่มกฎที่เฉพาะเจาะจงกับตัวแปรบิลด์แต่ละรายการ ให้กําหนดค่า เพิ่มเติม พร็อพเพอร์ตี้ proguardFiles สำหรับแต่ละรสชาติ ตัวอย่างเช่น พารามิเตอร์ ตัวอย่างต่อไปนี้เพิ่ม flavor2-rules.pro ลงใน "flavor 2" ปัจจุบัน ฟิลด์ เปิดตัว "flavor2" เวอร์ชัน ใช้ไฟล์กฎทั้ง 3 ไฟล์ เนื่องจากไฟล์ที่มาจาก จะมีการใช้การบล็อกการเผยแพร่ด้วย

ดึงดูด

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

เผยแพร่แอป

หากต้องการดูข้อมูลเพิ่มเติมเกี่ยวกับการเผยแพร่แอปไปยัง Google Play โปรดอ่านเผยแพร่แอปของคุณ

เซ็นชื่อบนแอปของคุณ

แม้ว่า Android Studio จะมีวิธีที่สะดวกในการกำหนดค่าการลงชื่อสำหรับการเปิดตัวแอป บิลด์จาก UI คุณสามารถกำหนดค่าบล็อก signingConfigs ใน build.gradle ของโมดูลได้ด้วยตนเอง ไฟล์:

ดึงดูด

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

Kotlin

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

นำข้อมูลการลงนามส่วนตัวออกจากโปรเจ็กต์

โดยค่าเริ่มต้น ระบบจะบันทึกการกำหนดค่าการรับรองเป็นข้อความธรรมดาในส่วน build.gradle ไฟล์ ถ้าคุณทำงานกับทีมหรือ โปรเจ็กต์โอเพนซอร์ส คุณย้ายข้อมูลที่ละเอียดอ่อนนี้ออกจากบิลด์ได้ โดยทำตามขั้นตอนดังนี้

สร้างไฟล์ชื่อ keystore.properties ในไดเรกทอรีรากของ โปรเจ็กต์และระบุข้อมูลต่อไปนี้ วันที่
```
storePassword=myStorePassword
keyPassword=myKeyPassword
keyAlias=myKeyAlias
storeFile=myStoreFileLocation
```

โหลด keystore.properties ในไฟล์ build.gradle ดังต่อไปนี้ (จะต้องอยู่ก่อนการบล็อก android):

ดึงดูด

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

Kotlin

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

ป้อนข้อมูลการลงชื่อที่จัดเก็บไว้ใน keystoreProperties ออบเจ็กต์:

ดึงดูด

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

Kotlin

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

คลิก Sync Now ในแถบการแจ้งเตือน

หากต้องการดูข้อมูลเพิ่มเติมเกี่ยวกับการลงนามแอป โปรดอ่านลงนามแอป

ทำให้การพัฒนาแอปง่ายขึ้น

เคล็ดลับต่อไปนี้ช่วยให้การพัฒนาแอป Android ของคุณง่ายขึ้น

ขณะสร้าง Gradle สร้างคลาส BuildConfig เพื่อให้ โค้ดของแอปจะตรวจสอบข้อมูลเกี่ยวกับบิลด์ปัจจุบันได้ นอกจากนี้ คุณยังเพิ่ม ช่องที่กำหนดเองไปยังคลาส BuildConfig จากบิลด์ Gradle ของคุณ ไฟล์การกำหนดค่าที่ใช้เมธอด buildConfigField() และการเข้าถึง ค่าเหล่านั้นในโค้ดรันไทม์ของแอป ในทำนองเดียวกัน คุณสามารถเพิ่มแหล่งข้อมูลของแอป ด้วย resValue()

ดึงดูด

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

ในโค้ดของแอป คุณสามารถเข้าถึงพร็อพเพอร์ตี้ได้ดังนี้

Kotlin

...
Log.i(TAG, BuildConfig.BUILD_TIME)
Log.i(TAG, getString(R.string.build_time))

Java

...
Log.i(TAG, BuildConfig.BUILD_TIME);
Log.i(TAG, getString(R.string.build_time));

ในบางกรณี คุณอาจต้องประกาศพร็อพเพอร์ตี้เดียวกันทั้งใน และไฟล์ Manifest (เช่น เมื่อประกาศหน่วยงานสำหรับ FileProvider) แทนที่จะอัปเดตที่พักเดียวกันในหลายตำแหน่งเพื่อให้สอดคล้องกับ เปลี่ยนแปลง กำหนดพร็อพเพอร์ตี้เดียวใน build.gradle ของโมดูล เพื่อให้พร้อมใช้งานทั้งในไฟล์ Manifest และโค้ดของคุณ ดังที่แสดงใน ดังตัวอย่างต่อไปนี้ หากต้องการดูข้อมูลเพิ่มเติม โปรดอ่านแทรกตัวแปรบิลด์ลงใน ไฟล์ Manifest

ดึงดูด

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    def filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders =
      [filesAuthority: filesAuthorityValue]
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

Kotlin

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    val filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders["filesAuthority"] = filesAuthorityValue
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

ในไฟล์ Manifest ของคุณ ให้เข้าถึงตัวยึดตำแหน่งดังนี้

<manifest>
  ...
  <application>
    ...
    <provider
      android:name="android.support.v4.content.FileProvider"
      android:authorities="${filesAuthority}"
      android:exported="false"
      android:grantUriPermissions="true">
      ...
    </provider>
  </application>
</manifest>

การเข้าถึงช่อง FILES_AUTHORITY ในโค้ดของแอป ประมาณนี้

Kotlin

...
val contentUri: Uri = FileProvider.getUriForFile(context, BuildConfig.FILES_AUTHORITY, myFile)

Java

...
Uri contentUri = FileProvider.getUriForFile(getContext(),
  BuildConfig.FILES_AUTHORITY,
  myFile);

เคล็ดลับและสูตร Gradle

จัดการโปรเจ็กต์และแหล่งที่มา

เปลี่ยนการกำหนดค่าชุดแหล่งที่มาเริ่มต้น

ดึงดูด

Kotlin

จัดการไลบรารีและทรัพยากร Dependency

กำหนดเป้าหมายบิลด์ที่เฉพาะเจาะจงด้วยการกำหนดค่าทรัพยากร Dependency

ดึงดูด

Kotlin

สร้างแอปเวอร์ชันต่างๆ

กำหนดค่ารหัสเวอร์ชันแบบไดนามิก

ดึงดูด

Kotlin

รวมหลากหลายรสชาติของผลิตภัณฑ์

ดึงดูด

Kotlin

กรองตัวแปร

ดึงดูด

Kotlin

ทดสอบแอป

กำหนดค่าตัวเลือก Lint

ดึงดูด

Kotlin

กำหนดการตั้งค่าไฟล์ Manifest สำหรับการใช้เครื่องมือ

ดึงดูด

Kotlin

เปลี่ยนประเภทบิลด์ทดสอบ

ดึงดูด

Kotlin

กำหนดค่าตัวเลือกการทดสอบ Gradle

ดึงดูด

Kotlin

ดึงดูด

Kotlin

เพิ่มประสิทธิภาพการสร้างของคุณ

ย่อโค้ดของคุณ

ดึงดูด

Kotlin

ดึงดูด

Kotlin

เผยแพร่แอป

เซ็นชื่อบนแอปของคุณ

ดึงดูด

Kotlin

นำข้อมูลการลงนามส่วนตัวออกจากโปรเจ็กต์

ดึงดูด

Kotlin

ดึงดูด

Kotlin

ทำให้การพัฒนาแอปง่ายขึ้น

แชร์ช่องที่กำหนดเองและค่าทรัพยากรกับโค้ดของแอป

ดึงดูด

Kotlin

Kotlin

Java

แชร์พร็อพเพอร์ตี้กับไฟล์ Manifest

ดึงดูด

Kotlin

Kotlin

Java